Есть ли функция VBA, которая ожидает имя встроенной константы и возвращает соответствующее значение? - PullRequest
Новая
       11

Есть ли функция VBA, которая ожидает имя встроенной константы и возвращает соответствующее значение?

0 голосов
/ 18 января 2020

Я пишу макрос для автоматизации форматирования определенных диапазонов ячеек. Чтобы сделать его как можно более универсальным, я хотел бы принять некоторые решения по форматированию во время выполнения, введя строки.

В настоящее время я использую оператор select-case-case, который мне кажется очень утомительным. 

Dim strInput As String
strInput = "xlDashDotDot"

Dim nConstVal As Integer

Select Case strInput
    Case "xlContinuous"
        nConstVal = xlContinuous

    Case "xlDash"
        nConstVal = xlDash

    Case "xlDashDot"
        nConstVal = xlDashDot

    Case "xlDashDotDot"
        nConstVal = xlDashDotDot

    Case "xlDot"
        nConstVal = xlDot

    Case "xlDouble"
        nConstVal = xlDouble

    Case "xlLineStyleNone"
        nConstVal = xlLineStyleNone

    Case "xlSlantDashDot"
        nConstVal = xlSlantDashDot
End Select

[...]

rng.Borders.LineStyle = nConstVal


Существует ли функция, которая принимает имя встроенной константы и возвращает соответствующее значение? 

Dim strInput As String
strInput = "xlDashDotDot"

Dim nConstVal As Integer

nConstVal = GetConstVal(strInput)

1 Ответ

1 голос
/ 18 января 2020

Инструменты - Ссылки - TypeLib Information.

Тогда: 

Option Explicit

' Cache this variable on module level to not reload it on each call
Private mLib As TLI.TypeLibInfo

Private Function EnumValueFromString(ByVal Constants As TLI.Constants, ByVal EnumName As String, ByVal EnumValueName As String) As Variant
  EnumValueFromString = Constants.NamedItem(EnumName).GetMember(EnumValueName).Value
End Function


Sub Test()
  With New TLI.TLIApplication
    Set mLib = .TypeLibInfoFromFile(Application.Path & "\EXCEL.EXE")
  End With


  Debug.Print EnumValueFromString(mLib.Constants, "XlLineStyle", "xlDashDot")
  Debug.Print EnumValueFromString(mLib.Constants, "XlLineStyle", "xlDashDotDot")
  Debug.Print EnumValueFromString(mLib.Constants, "XlLineStyle", "xlDot")
End Sub
...