Добавление общего атрибута ко всем цепям в рекурсии - PullRequest
Новая
       28

Добавление общего атрибута ко всем цепям в рекурсии

0 голосов
/ 02 апреля 2020

Последующий вопрос к: Ограничить рекурсию одним глубоким l oop и назначить точный идентификатор всем элементам

Этот код собирает рекурсию. Необходимо, чтобы все элементы рекурсии одновременно получали атрибут COMMON-ID со значением из первого элемента цепочки. Этот первый элемент также имеет атрибуцию STATUS="0". Другие элементы имеют STATUS="1" (для решения это может быть полезно).

1-источник 

<root>
  <object id="a" id-3="COMMON-ID-1" STATUS="0"/>
  <object id="b" id-3="COMMON-ID-2" STATUS="0"/>
  <object id="c" id-3="COMMON-ID-3" STATUS="0"/>

  <object id="aa" parent-id="a" id-3="value" STATUS="1"/>
  <object id="bb" parent-id="b" id-3="value" STATUS="1"/>
  <object id="cc" parent-id="c" id-3="value" STATUS="1"/>
  <object id="aaa" parent-id="aa" id-3="value" STATUS="1"/>
  <object id="bbb" parent-id="bb" id-3="value" STATUS="1"/>
  <object id="ccc" parent-id="cc" id-3="value" STATUS="1"/>
  <object id="bbbb" parent-id="bbb" id-3="value" STATUS="1"/>
  <object id="cccc" parent-id="ccc" id-3="value" STATUS="1"/>
  <object id="bbbbb" parent-id="bbbb" id-3="value" STATUS="1"/>
</root>

2-присутствует XSLT (не назначать COMMON-ID ) 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="child" match="object" use="@parent-id" />

<xsl:template match="/root">
    <!-- generate chains -->
    <xsl:variable name="chains">
        <xsl:apply-templates select="object[not(@parent-id)]"/>
    </xsl:variable>
    <!-- find the longest chain -->
    <xsl:for-each select="exsl:node-set($chains)/object">
        <xsl:sort select="count(descendant::object)" data-type="number" order="descending"/>
        <xsl:if test="position()">
            <xsl:copy-of select="."/>
        </xsl:if>
    </xsl:for-each>
</xsl:template>

<xsl:template match="object">
    <xsl:copy>
        <xsl:copy-of select="@*"/>
        <xsl:apply-templates select="key('child', @id)"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

3 желаемых выхода 

<?xml version="1.0" encoding="UTF-8"?>
<object id="b" id-3="COMMON-ID-1" STATUS="0" COMMON-ID="COMMON-ID-2">
  <object id="bb" parent-id="b" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-2>
    <object id="bbb" parent-id="bb" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-2>
      <object id="bbbb" parent-id="bbb" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-2>
        <object id="bbbbb" parent-id="bbbb" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-2/>
      </object>
    </object>
  </object>
</object>
<object id="c"  id-3="COMMON-ID-3" STATUS="0" COMMON-ID="COMMON-ID-3">
  <object id="cc" parent-id="c" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-3">
    <object id="ccc" parent-id="cc" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-3">
      <object id="cccc" parent-id="ccc" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-3"/>
    </object>
  </object>
</object>
<object id="a" id-3="COMMON-ID-1" STATUS="0" COMMON-ID="COMMON-ID-1">
  <object id="aa" parent-id="a" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-1">
    <object id="aaa" parent-id="aa" id-3="COMMON-ID-1" STATUS="1" COMMON-ID="COMMON-ID-1"/>
  </object>
</object>

1 Ответ

1 голос
/ 02 апреля 2020

Измените ваш второй шаблон на: 

<xsl:template match="object">
    <xsl:param name="common-id" select="@id-3"/>
    <xsl:copy>
        <xsl:copy-of select="@*"/>
        <xsl:attribute name="COMMON-ID">
            <xsl:value-of select="$common-id"/>
        </xsl:attribute>
        <xsl:apply-templates select="key('child', @id)">
            <xsl:with-param name="common-id" select="$common-id"/>
        </xsl:apply-templates>
    </xsl:copy>
</xsl:template>
...