(Рекурсия) автоинкремент для всех элементов уровня глубины и сохранение пути наследственности в цепочке - PullRequest
Новая
       23

(Рекурсия) автоинкремент для всех элементов уровня глубины и сохранение пути наследственности в цепочке

0 голосов
/ 07 апреля 2020

Можно ли создать уникальный идентификатор (здесь, в качестве значения атрибута "путь"), реализуя принцип приращения?

  • для рекурсии глубины 3 уровня, например, это будет выглядеть как "1 / 1/1 "или" 1/1/2 "- если на третьем уровне есть брат или сестра
  • Я могу допустить, что с технической точки зрения реализации XSLT было бы полезно использовать префикс уровня перед +1 подсчет приращений. Этот случай также будет правильным. главное - в сборку уникальный идентификатор («путь»)

1-источник 

<root>

  <object id="a" id-3="value"/>
  <object id="b" id-3="value"/>
  <object id="c" id-3="value"/>

  <object id="aa" parent-id="a" id-3="value"/>
  <object id="aaa" parent-id="aa" id-3="value"/>
  <object id="aaaa" parent-id="aaa" id-3="value"/>

  <object id="bb" parent-id="b" id-3="value"/>
  <object id="bbb" parent-id="bb" id-3="value"/>
  <object id="bbbb-1" parent-id="bbb" id-3="value"/>    <!-- note - siblings-->
  <object id="bbbb-2" parent-id="bbb" id-3="value"/>    <!-- note - siblings-->

  <object id="cc" parent-id="c" id-3="value"/>
  <object id="ccc" parent-id="cc" id-3="value"/>
  <object id="cccc" parent-id="ccc" id-3="value"/>

</root>

2-XSLT ( без "пути") 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:exslt="http://exslt.org/common">
  <xsl:key name="object-by-id" match="object" use="@id"/>
  <xsl:key name="object-by-parent-id" match="object" use="string(@parent-id)"/>

  <xsl:variable name="fold-rtf">
    <xsl:apply-templates select="/" mode="fold"/>
  </xsl:variable>
  <xsl:variable name="folded-tree" select="exslt:node-set($fold-rtf)"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="object/@*[last()]">
    <xsl:variable name="current" select=".."/>
    <xsl:copy/>
    <xsl:for-each select="$folded-tree">
      <xsl:for-each select="key('object-by-id',$current/@id)">

        <!-- ============================= -->

        <xsl:for-each select="ancestor-or-self::*">
          <xsl:attribute name="path">
            <xsl:value-of select="position()"/>
          </xsl:attribute>
        </xsl:for-each>
        <!-- ============================= -->

      </xsl:for-each>
    </xsl:for-each>
  </xsl:template>

  <xsl:template match="/|*" mode="fold">
    <xsl:copy>
      <xsl:copy-of select="@*"/>
      <xsl:apply-templates select="key('object-by-parent-id',string(@id))" mode="fold">
      </xsl:apply-templates>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

3-предполагаемый вывод 

<root>

  <object id="a" id-3="value" path="1"/>
  <object id="b" id-3="value" path="2"/>
  <object id="c" id-3="value" path="3"/>

  <object id="aa" parent-id="a" id-3="value"        path="1/1"/>
  <object id="aaa" parent-id="aa" id-3="value"      path="1/1/1"/>
  <object id="aaaa" parent-id="aa" id-3="value"     path="1/1/1/1"/>

  <object id="bb" parent-id="b" id-3="value"        path="2/1"/>
  <object id="bbb" parent-id="bb" id-3="value"      path="2/1/1"/>
  <object id="bbbb-1" parent-id="bbb" id-3="value"  path="2/1/1/1"/>    <!-- note - siblings-->
  <object id="bbbb-2" parent-id="bbb" id-3="value"  path="2/1/1/2"/>    <!-- note - siblings-->

  <object id="cc" parent-id="c" id-3="value"        path="3/1"/>
  <object id="ccc" parent-id="cc" id-3="value"      path="3/1/1"/>
  <object id="cccc" parent-id="ccc" id-3="value"    path="3/1/1/1"/>

</root>

1 Ответ

1 голос
/ 07 апреля 2020

Я думаю, вы можете использовать xsl:number: 

  <xsl:template match="object/@*[last()]">
    <xsl:variable name="current" select=".."/>
    <xsl:copy/>
    <xsl:for-each select="$folded-tree">
      <xsl:for-each select="key('object-by-id',$current/@id)">


        <xsl:attribute name="path">
            <xsl:number level="multiple" format="1/1"/>
        </xsl:attribute>

      </xsl:for-each>
    </xsl:for-each>
  </xsl:template>

https://xsltfiddle.liberty-development.net/pNmC4HV

...