Пакетный файл: git оформление ветки с использованием переменных - PullRequest
Новая
       17

Пакетный файл: git оформление ветки с использованием переменных

1 голос
/ 30 апреля 2020

У меня проблема с настройкой этой партии. Я хочу попасть в каталоги моего проекта, git fetch -all, переключить ветку для разработки, получить и go вернуться к моей фактической ветке. Пока я преуспел в этом, но проверить невозможно ветвление с использованием переменных Я не знаю, почему ..

Короче говоря, я хочу достичь (при разработке ветки): 

set current_branch=custom
git checkout %current_branch%

Вот полный пакетный файл 

@echo off
SET project_array="c:\example\project01" "c:\example\project02"
for %%a in (%project_array%) do (
    echo ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
    echo fetching datas for project at: %%a
    cd %%a
    @echo on
    for /F "tokens=*" %%i in ('git branch --show-current') do set current_branch=%%i
    git fetch --all
    git checkout develop
    git pull
    git checkout %current_branch%
    @echo off
)
PAUSE

1 Ответ

1 голос
/ 30 апреля 2020

попробуйте это (не проверено): 

@echo off
SET "project_array="c:\example\project01" "c:\example\project02""
setlocal enableDelayedExpansion
for %%a in (%project_array%) do (
    echo ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
    echo fetching datas for project at: %%a
    cd %%a
    @echo on
    for /F "tokens=*" %%i in ('git branch --show-current') do set current_branch=%%i
    git fetch --all
    git checkout develop
    git pull
    git checkout !current_branch!
    @echo off
)
PAUSE

Подробнее о Отсроченное расширение

...