Многоколоночный график Gnuplot с использованием заголовков CSV - PullRequest
Новая
       46

Многоколоночный график Gnuplot с использованием заголовков CSV

0 голосов
/ 10 июля 2020

gnuplot через блокнот Jupyter

Я изо всех сил пытаюсь получить столбчатую диаграмму / гистограмму с несколькими столбцами с моим вводом в виде CSV с заголовками. А также ключ, показывающий атрибуты {wcfiles, wclines, clocfiles, cloclines}. 

$summary << EOD
browser,wcfiles,wclines,clocfiles,cloclines
webkitgtk-2.28.2,19472,4710385,18620,3120740
firefox-78.0.1,289298,43627834,240137,24371602
chromium-83.0.4103.116,420343,100340817,269434,49597826
EOD
set datafile separator ','
set yrange [0:*]      # start at zero, find max from the data
set style fill solid border -1
set ytics format "%.0s%c" #  will generate labels 100k 200k 300k ... 1M
set title 'sloc the Web'
plot '$summary' using 0:2:($0+1):xtic(1) with boxes lc variable,\
   "" u 3 title "wclines",\
   "" u 4 title "clocfiles"

1 Ответ

1 голос
/ 11 июля 2020

Проверьте примеры, упомянутые @Ethan. В вашем случае вам следует set logscale y, иначе будет сложно визуализировать значения с разницей в несколько порядков.

Код: 

### histogram clustered
reset session

$Data <<EOD
browser,wcfiles,wclines,clocfiles,cloclines
webkitgtk-2.28.2,19472,4710385,18620,3120740
firefox-78.0.1,289298,43627834,240137,24371602
chromium-83.0.4103.116,420343,100340817,269434,49597826
EOD

set datafile separator ','
set title 'sloc the Web'

set yrange [1000:*]
set logscale y
set ytics format "%.0s%c"

set style data histogram
set style histogram cluster gap 1
set style fill solid border -1
set boxwidth 0.9

plot $Data u 2:xtic(1) ti col,\
     '' u 3 ti col,\
     '' u 4 ti col
### end of code

Результат:

введите описание изображения здесь

...