Google Таблицы подсчитывают, если последовательные числа меньше

Question

У меня есть набор данных в столбце A следующего вида:

A       B
150    155
200
140
122
250
299

Я хотел бы получить ответ «Да», если 2 или более последовательных числа меньше значения в B1 (155 ), пока моя формула:

=if(frequency(FILTER(A1:A,A1:A<B1),A1:A=2)>0,"Yes","No")

Однако, похоже, это не работает, есть какие-нибудь подсказки?

Answer 1

попробуйте:

=ARRAYFORMULA(IF(MAX(SUBSTITUTE(SPLIT(QUERY(
 IF((A1:A<>"")*(A1:A<B1), 1, 0),, 9^9), 0), " ", )*1)>1, "yes", "no"))

---

for more than B1 use:

=ARRAYFORMULA(IF(MAX(SUBSTITUTE(SPLIT(QUERY(
 IF(A1:A>B1, 1, 0),, 9^9), 0), " ", )*1)>1, "yes", "no"))

введите описание изображения здесь

Answer 2

Если вам интересно, вы можете сделать это, используя Frequency, но я не думаю, что Frequency работает так, как вы ожидаете. Первый параметр - это данные, которые вы группируете, а второй - это диапазон ячеек или список точек разреза, которые вы используете для группировки данных. Таким образом, хитрость заключается в использовании значений <155 для получения списка номеров строк (данных) и значений> = 155 для получения другого списка номеров строк (точек вырезания) следующим образом:

=ArrayFormula(if(Max(
 frequency(
  if((A:A<B1)*(A:A<>""),row(A:A)),
  if((A:A>=B1)*(A:A<>""),row(A:A)))
 )>=2,
"Yes","No"))

введите описание изображения здесь

Нет особых преимуществ в использовании этого способа, за исключением того, что он также работает в Excel.