Тени против перегрузок в VB.NET

Question

Когда у нас есть new в C #, что лично я вижу только как обходной путь для переопределения свойства, которое не имеет виртуального / переопределяемого объявления, в VB.NET у нас есть две «концепции» Shadows и Overloads.

В каком случае предпочитаете одно другому?

Answer 1

Я на самом деле подтвердил, скомпилировав тот же код с Shadows против Overloads для метода с идентичным именем и сигнатурой в базовом классе и просмотрев вывод из ildasm для обоих. Единственное отличие состоит в том, что в случае Overloads указывается hidebysig.

Значение этого лучше всего объяснить Джоном Скитом в этом ответе .

Но это просто означает, что существует реальная разница, если базовый класс имеет перегрузки переопределяемого метода:

• Shadows вызовет всех из этих перегрузки не могут быть вызваны через производный класс, где как
• Overloads заменяет только метод one .

Обратите внимание, что это только языковая конструкция и не применяется CLI (то есть C # и VB.NET обеспечивают это, но другие языки не могут).

Простой пример кода:

Module Module1

Sub Main()
    Dim a1 As C1 = New C2
    Dim a2 As New C2
    a1.M1()
    a2.M1()
    a1.M2()
    a2.M2()
    a1.M3()
    a2.M3()

    a1.M1(1)
    ' Overloads on M1() allows the M1(int) to be inherited/called.
    a2.M1(1)
    a1.M2(1)
    ' Shadows on M2() does not allow M2(int) to be called.
    'a2.M2(1)
    a1.M3(1)
    ' Shadows on M3() does not allow M3(int) to be called, even though it is Overridable.
    'a2.M3(1)

    If Debugger.IsAttached Then _
        Console.ReadLine()
End Sub

End Module

Class C1
Public Sub M1()
    Console.WriteLine("C1.M1")
End Sub
Public Sub M1(ByVal i As Integer)
    Console.WriteLine("C1.M1(int)")
End Sub
Public Sub M2()
    Console.WriteLine("C1.M2")
End Sub
Public Sub M2(ByVal i As Integer)
    Console.WriteLine("C1.M2(int)")
End Sub
Public Overridable Sub M3()
    Console.WriteLine("C1.M3")
End Sub
Public Overridable Sub M3(ByVal i As Integer)
    Console.WriteLine("C1.M3(int)")
End Sub
End Class

Class C2
Inherits C1
Public Overloads Sub M1()
    Console.WriteLine("C2.M1")
End Sub
Public Shadows Sub M2()
    Console.WriteLine("C2.M2")
End Sub
Public Shadows Sub M3()
    Console.WriteLine("C2.M3")
End Sub
' At compile time the different errors below show the variation.
' (Note these errors are the same irrespective of the ordering of the C2 methods.)
' Error: 'Public Overrides Sub M1(i As Integer)' cannot override 'Public Sub M1(i As Integer)' because it is not declared 'Overridable'.
'Public Overrides Sub M1(ByVal i As Integer)
'    Console.WriteLine("C2.M1(int)")
'End Sub
' Errors: sub 'M3' cannot be declared 'Overrides' because it does not override a sub in a base class.
'         sub 'M3' must be declared 'Shadows' because another member with this name is declared 'Shadows'.
'Public Overrides Sub M3(ByVal i As Integer)
'    Console.WriteLine("C2.M3(int)")
'End Sub
End Class

Вывод вышеуказанного:

C1.M1
C2.M1
C1.M2
C2.M2
C1.M3
C2.M3
C1.M1(int)
C1.M1(int)
C1.M2(int)
C1.M3(int)

Выходные данные показывают, что Shadows вызовы используются, когда C2 вызывается напрямую, а не когда вызывается косвенно через C1.

Answer 2

Есть три тесно связанных понятия; переопределение, затенение и перегрузка.

Переопределение - это когда вы создаете новую реализацию для виртуального метода.

Затенение - это когда вы создаете новую не виртуальную реализацию для метода.

Перегрузка - это когда вы добавляете метод с тем же именем, но разными параметрами.

Все три концепции доступны как в C #, так и в VB.

Answer 3

Shadows для случаев, когда ваш базовый класс равен Function SomeMethod() As String и вы хотите иметь Function SomeMethod() As Integer. В основном, чтобы изменить тип возвращаемого значения.

Overloads для случая, когда ваш базовый класс равен Function SomeMethod() As String, и вы хотите добавить параметр, такой как Function SomeMethod(ByVal value As Integer) As String.