Можете ли вы заставить скаляр или ссылку на массив быть массивом в Perl? - PullRequest
Новая
       39

Можете ли вы заставить скаляр или ссылку на массив быть массивом в Perl?

28 голосов
/ 06 августа 2008

У меня есть переменная perl $results, которая возвращается из службы. Значение должно быть массивом, а $results должно быть ссылкой на массив. Однако если в массиве содержится только один элемент, этому значению будет присвоено значение $results, а не ссылочный массив, содержащий этот элемент.

Я хочу сделать цикл foreach для ожидаемого массива. Не проверяя ref($results) eq 'ARRAY', есть ли способ получить что-то эквивалентное следующему: 

foreach my $result (@$results) {
    # Process $result
}

Этот конкретный пример кода будет работать для справки, но будет жаловаться на простой скаляр.

РЕДАКТИРОВАТЬ: Я должен уточнить, что я не могу изменить то, что возвращается от службы. Проблема заключается в том, что значение будет скалярным, если есть только одно значение, и ссылкой на массив, если существует более одного значения.

Ответы [ 6 ]

26 голосов
/ 06 августа 2008

я не уверен, что есть другой способ, кроме: 

$result = [ $result ]   if ref($result) ne 'ARRAY';  
foreach .....
12 голосов
/ 19 августа 2008

Другим решением было бы заключить вызов в сервер и заставить его всегда возвращать массив, чтобы упростить остаток вашей жизни: 

sub call_to_service
{
    my $returnValue = service::call();

    if (ref($returnValue) eq "ARRAY")
    {
        return($returnValue);
    }
    else
    {
       return( [$returnValue] );
    }
}

Тогда вы всегда можете знать, что вернете ссылку на массив, даже если это был только один элемент. 

foreach my $item (@{call_to_service()})
{
  ...
}
2 голосов
/ 13 октября 2008

Ну, если вы не можете сделать ... 

for my $result ( ref $results eq 'ARRAY' ? @$results : $results ) {
    # Process result
}

или это ... 

for my $result ( ! ref $results ? $results : @$results ) {
    # Process result
}

тогда вам, возможно, придется попробовать что-то пугающе волосатое, как это! .... 

for my $result ( eval { @$results }, eval $results ) {
    # Process result
}

и чтобы избежать этой опасной строки, она становится ужасно уродливой !! .... 

for my $result ( eval { $results->[0] } || $results, eval { @$results[1 .. $#{ $results }] } ) {
    # Process result
}

PS. Я предпочел бы абстрагировать его в примере под названием call_to_service (), представленном reatmon.

0 голосов
/ 23 ноября 2016

Вы можете сделать это так: 

my @some_array
push (@some_array, results);
foreach my $elt(@some_array){
  #do something
}
0 голосов
/ 15 августа 2008

Я бы перефакторил код внутри цикла и затем сделал бы 

if( ref $results eq 'ARRAY' ){
    my_sub($result) for my $result (@$results);
}else{
    my_sub($results);
}

Конечно, я бы сделал это, только если код в цикле был нетривиальным.

0 голосов
/ 06 августа 2008

Я только что проверил это с: 

#!/usr/bin/perl -w
use strict;

sub testit {

 my @ret = ();
 if (shift){
   push @ret,1;
   push @ret,2;
   push @ret,3;
}else{
  push @ret,"oneonly";
}

return \@ret;
}

foreach my $r (@{testit(1)}){
  print $r." test1\n";
}
foreach my $r (@{testit()}){
   print $r." test2\n";
}

Кажется, все работает нормально, так что я думаю, что это как-то связано с возвращением результата из службы? Если у вас нет контроля над возвратом сервиса, его может быть трудно взломать

...