OSX, G / AWK, Bash - «недопустимый оператор, неопределенная строка» и отсутствие вывода файла - PullRequest
Новая
       11

OSX, G / AWK, Bash - «недопустимый оператор, неопределенная строка» и отсутствие вывода файла

0 голосов
/ 13 апреля 2010

У меня есть скрипт, который кто-то из SO любезно предоставил, чтобы решить проблему, с которой я столкнулся. Однако у меня возникли некоторые проблемы, заставляющие его работать на OSX. 

gawk --version
GNU Awk 3.1.6

awk --version
awk version 20100208

Первоначальный источник: 

awk -F, -vOFS=, -vc=1 '
NR == 1 {
    for (i=1; i<NF; i++) {
        if ($i != "") {
            g[c]=i;
            f[c++]=$i
        }
    }
}
NR>2 {
    for (i=1; i < c; i++) {
        print $1,$2, $g[i] > "output_"f[i]".csv
    }
}' data.csv

При запуске скрипта выдается следующая ошибка: 

awk: syntax error at source line 12
context is print $1,$2, $g[i] > >>>  "output_"f <<< [i]".csv
awk: illegal statement at source line 13

Судя по всему, переменная [i] не была изменена в выходном файле, но я не знаю почему.

Если я изменил AWK на GAWK и запустил оригинальный скрипт, то вот что получилось: 

gawk: cmd. line:11:             print $1,$2, $g[i] > "output_"f[i]".csv
gawk: cmd. line:11:                                               ^ unterminated string

Поэтому я редактирую соответствующую строку, чтобы исправить неопределенную строку 

print $1,$2, $g[i] > "output_"f[i]".csv"

Затем он проходит нормально, не выдает ошибок, но нет выходных файлов.

Есть идеи? Я провел большую часть прошлой ночи и этим утром поливал это.

Пример входного файла: 

,,L1,,,L2,,,L3,,,L4,,,L5,,,L6,,,L7,,,L8,,,L9,,,L10,,,L11,
Title,r/t,needed,actual,Inst,needed,actual,Inst,needed,actual,Inst,needed,actual,Inst,neede d,actual,Inst,needed,actual,Inst,needed,actual,Inst,needed,actual,Inst,needed,actual,Inst,needed,actual,Inst,needed,actual,Inst
EXAMPLEfoo,60,6,6,6,0,0,0,0,0,0,6,6,6,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
EXAMPLEbar,30,6,6,12,6,7,14,6,6,12,6,6,12,6,8,16,6,7,14,6,7.5,15,6,6,12,6,8,16,6,0,0,6,7,14
EXAMPLE1,60,3,3,3,3,5,5,3,4,4,3,3,3,3,6,6,3,4,4,3,3,3,3,4,4,3,8,8,3,0,0,3,4,4
EXAMPLE2,120,6,6,3,0,0,0,6,8,4,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
EXAMPLE3,60,6,6,6,6,8,8,6,6,6,6,6,6,0,0,0,0,0,0,6,8,8,6,6,6,0,0,0,0,0,0,0,10,10
EXAMPLE4,30,6,6,12,6,7,14,6,6,12,6,6,12,3,5.5,11,6,7.5,15,6,6,12,6,0,0,6,9,18,6,0,0,6,6.5,13

И приведенный пример должен быть

Так что для L1 пример выхода будет выглядеть так: 

EXAMPLEfoo,60,6
EXAMPLEbar,30,6
EXAMPLE1,60,3
EXAMPLE2,120,6
EXAMPLE3,60,6
EXAMPLE4,30,6

А для L2: 

EXAMPLEfoo,60,0
EXAMPLEbar,30,6
EXAMPLE1,60,3
EXAMPLE2,120,0
EXAMPLE3,60,6
EXAMPLE4,30,6

1 Ответ

1 голос
/ 15 апреля 2010

Я вижу две проблемы (на платформе OS X):

  1. Команда awk в OS X не поддерживает флаг -v. Мы можем исправить это, используя шаблон BEGIN.
  2. OS X awk не нравится, как выходной файл создается в строке печати. ​​

Вот мое решение, которое работает как на Mac OS X Snow Leopard, так и на Red Hat Linux 4.x: 

awk -F, '
BEGIN { OFS=","; c=1 } # FIX problem 1
NR == 1 {
    for (i=1; i<NF; i++) {
        if ($i != "") {
            g[c]=i;
            f[c++]=$i
        }
    }
}
NR>2 {
    for (i=1; i < c; i++) {
        outfile=sprintf("output_%s.csv", f[i]) # FIX problem 2
        print $1,$2, $g[i] > outfile
    }
}' data.csv
...