1136: неверное количество аргументов. Ожидаемое 0. AS3 Flash Cs4

Question

По сути, я работаю над книгой под названием .. Основа Actionscript 3.0, анимация, заставляющая вещи двигаться.

Сейчас я в главе 9 - обнаружение столкновений. В двух строках моего кода я получаю ошибку 1135, сообщая, что у меня неверное количество аргументов. Кто-нибудь может мне помочь, почему это может быть?

package
{
    import flash.display.Sprite;
    import flash.events.Event;
    public class Bubbles extends Sprite
    {
        private var balls:Array;
        private var numBalls:Number = 10;
        private var centerBall:Ball;
        private var bounce:Number = -1;
        private var spring:Number = 0.2;

        public function Bubbles()
        {
            init();
        }

        private function init():void
        {
            balls = new Array();
            centerBall = new Ball(100, 0xcccccc);
            addChild(centerBall);
            centerBall.x = stage.stageWidth / 2;
            centerBall.y = stage.stageHeight / 2;
            for(var i:uint = 0; i < numBalls; i++)
            {
                var ball:Ball = new Ball(Math.random() *
                40 + 5,
                Math.random() * 0xffffff);
                ball.x = Math.random() * stage.stageWidth;
                ball.y = Math.random() * stage.stageHeight;
                ball.vx = Math.random() * 6 - 3;
                ball.vy = Math.random() * 6 - 3;
                addChild(ball);
                balls.push(ball);
            }
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
        }

        private function onEnterFrame(event:Event):void
        {
            for(var i:uint = 0; i < numBalls; i++)
            {
                var ball:Ball = balls[i];
                move(ball);
                var dx:Number = ball.x - centerBall.x;
                var dy:Number = ball.y - centerBall.y;
                var dist:Number = Math.sqrt(dx * dx + dy * dy);
                var minDist:Number = ball.radius + centerBall.radius;
                if(dist < minDist)
                {
                    var angle:Number = Math.atan2(dy, dx);
                    var tx:Number = centerBall.x +
                    Math.cos(angle) * minDist;
                    var ty:Number = centerBall.y +
                    Math.sin(angle) * minDist;
                    ball.vx += (tx - ball.x) * spring;
                    ball.vy += (ty - ball.y) * spring;
                }
            }
       }
       // Having Trouble Here:
       private function move(ball:Ball):void
       {
           ball.x += ball.vx;
           ball.y += ball.vy;
           if(ball.x + ball.radius > stage.stageWidth)
           {
               ball.x = stage.stageWidth - ball.radius;
               ball.vx *= bounce;
           }
           else if(ball.x - ball.radius < 0)
           {
               ball.x = ball.radius;
               ball.vx *= bounce;
           }
           // Having Trouble Here:
           if(ball.y + ball.radius > stage.stageHeight)
           {
               ball.y = stage.stageHeight - ball.radius;
               ball.vy *= bounce;
           }
           else if(ball.y - ball.radius < 0)
           {
               ball.y = ball.radius;
               ball.vy *= bounce;
           }
        }
    }
}

Я указал линии, с которыми у меня проблемы.

Answer 1

Следующие строки являются виновниками.

centerBall = new Ball(100, 0xcccccc);
var ball:Ball = new Ball(Math.random() * 40 + 5, Math.random() * 0xffffff);

Вы пытаетесь передать аргументы конструктору Ball, который принимает нулевые аргументы. Измените их на

centerBall = new Ball();
var ball:Ball = new Ball();

соответственно и будет работать. Если вы действительно хотите передать детали инициализации, создайте файл Ball.as и назначьте его для фрагмента ролика на сцене. Теперь объявите конструктор класса Ball для принятия этих двух аргументов и инициализируйте переменные (радиус и цвет) внутри конструктора.

---

Ball.as будет выглядеть примерно так:

package
{
  public class Ball extends MovieClip
  {
    public function Ball(r:Number, col:uint)
    {
      this.radius = r;
      this.color = col;
    }
  }
}