Как перебрать Hash (Хэшей) в Perl?

Question

У меня есть Hash, где значения ключей - другие хэши

Пример: {'key' => {'key2' => {'key3' => 'value'}}}

Как я могу пройти через эту структуру?

Answer 1

Этот ответ основан на идее Дэйва Хинтона, а именно на написании подпрограммы общего назначения для обхода хеш-структуры. Такой обработчик хэшей берет ссылку на код и просто вызывает этот код для каждого конечного узла в хэше.

При таком подходе один и тот же хеш-обходчик может использоваться для многих вещей, в зависимости от того, какой обратный вызов мы ему даем. Для еще большей гибкости вам потребуется передать два обратных вызова - один для вызова, когда значение является ссылкой на хеш, а другой для вызова, когда это обычное скалярное значение. Подобные стратегии более подробно рассматриваются в превосходной книге Марка Джейсона Домина, Perl высшего порядка .

use strict;
use warnings;

sub hash_walk {
    my ($hash, $key_list, $callback) = @_;
    while (my ($k, $v) = each %$hash) {
        # Keep track of the hierarchy of keys, in case
        # our callback needs it.
        push @$key_list, $k;

        if (ref($v) eq 'HASH') {
            # Recurse.
            hash_walk($v, $key_list, $callback);
        }
        else {
            # Otherwise, invoke our callback, passing it
            # the current key and value, along with the
            # full parentage of that key.
            $callback->($k, $v, $key_list);
        }

        pop @$key_list;
    }
}

my %data = (
    a => {
        ab => 1,
        ac => 2,
        ad => {
            ada => 3,
            adb => 4,
            adc => {
                adca => 5,
                adcb => 6,
            },
        },
    },
    b => 7,
    c => {
        ca => 8,
        cb => {
            cba => 9,
            cbb => 10,
        },
    },
);

sub print_keys_and_value {
    my ($k, $v, $key_list) = @_;
    printf "k = %-8s  v = %-4s  key_list = [%s]\n", $k, $v, "@$key_list";
}

hash_walk(\%data, [], \&print_keys_and_value);

Answer 2

Это то, что вы хотите? (Непроверенные)

sub for_hash {
    my ($hash, $fn) = @_;
    while (my ($key, $value) = each %$hash) {
        if ('HASH' eq ref $value) {
            for_hash $value, $fn;
        }
        else {
            $fn->($value);
        }
    }
}

my $example = {'key' => {'key2' => {'key3' => 'value'}}};
for_hash $example, sub {
    my ($value) = @_;
    # Do something with $value...
};

Answer 3

Предыдущие ответы показывают, как создать собственное решение, которое полезно сделать хотя бы один раз, чтобы вы поняли, как работают ссылки на Perl и структуры данных. Вы обязательно должны прочитать perldoc perldsc и perldoc perlref , если вы этого еще не сделали.

Однако вам не нужно писать собственное решение - в CPAN уже есть модуль, который будет перебирать произвольно сложные структуры данных: Data :: Visitor .

Answer 4

Этот пост может быть полезен.

foreach my $key (keys %hash) {
    foreach my $key2 (keys %{ $hash{$key} }) {
        foreach my $key3 (keys %{ $hash{$key}{$key2} }) {
            $value = $hash{$key}{$key2}->{$key3};
            # .
            # .
            # Do something with $value
            # .
            # .
            # .
        }
    }
}

Answer 5

Также, пожалуйста, прочитайте perldoc perldsc . Вы можете узнать о хэшах глубже

Answer 6

Это не совсем новый ответ, но я хотел бы поделиться, как сделать больше, чем просто распечатайте все значения хеша рекурсивно, но также измените их при необходимости.

Вот моя очень небольшая модификация ответа dave4420, в которой значение передается обратному вызову в качестве ссылки, поэтому мой обратный вызов процедура может затем изменить каждое значение в хэше.

Мне также пришлось перестраивать хэш, пока каждый цикл создает копии не ссылки.

sub hash_walk {
   my $self = shift;
    my ($hash, $key_list, $callback) = @_;
    while (my ($k, $v) = each %$hash) {
        # Keep track of the hierarchy of keys, in case
        # our callback needs it.
        push @$key_list, $k;

        if (ref($v) eq 'HASH') {
            # Recurse.
            $self->hash_walk($v, $key_list, $callback);
        }
        else {
            # Otherwise, invoke our callback, passing it
            # the current key and value, along with the
            # full parentage of that key.
            $callback->($k, \$v, $key_list);
        }

        pop @$key_list;
        # Replace old hash values with the new ones
        $hash->{$k} = $v;
    }
}

hash_walk(\%prj, [], \&replace_all_val_strings);

sub replace_all_val_strings {
    my ($k, $v, $key_list) = @_;
    printf "k = %-8s  v = %-4s  key_list = [%s]\n", $k, $$v, "@$key_list";
    $$v =~ s/oldstr/newstr/;
    printf "k = %-8s  v = %-4s  key_list = [%s]\n", $k, $$v, "@$key_list";
}

Answer 7

Если вы используете Perl в качестве «интерпретатора CPAN», то в дополнение к Data::Visitor и Data::Deep есть супер простой Data::Traverse:

use Data::Traverse qw(traverse);

my %test_hash = (
  q => [qw/1 2 3 4/],
  w => [qw/4 6 5 7/],
  e => ["8"],
  r => { 
         r => "9"  ,
         t => "10" ,
         y => "11" ,
      } ,
);

traverse { next if /ARRAY/; print "$a => $b\n" if /HASH/ && $b > 8 } \%test_hash;

выход

t => 10
y => 11

$a и $b здесь обрабатываются как специальные переменные (как с sort()), когда они находятся внутри функции traverse(). Data::Traverse - это очень простой, но чрезвычайно полезный модуль без зависимостей без CORE.

Answer 8

Вам придется пройти через это дважды. т.е.

while ( ($family, $roles) = each %HoH ) {
   print "$family: ";
   while ( ($role, $person) = each %$roles ) {
      print "$role=$person ";
   }
print "\n";
}

Answer 9

foreach my $keyname (keys(%foo) {
  my $subhash = $foo{$keyname};
  # stuff with $subhash as the value at $keyname
}