Аванс с текущей позиции, Tweener, AS3 - PullRequest
Новая
       25

Аванс с текущей позиции, Tweener, AS3

0 голосов
/ 17 марта 2010

Я хочу, чтобы моя анимация продвигалась на 120 пикселей каждый раз. Вместо этого моя анимация возвращается к основанию, а не продвигается с новой позиции. Он предполагает новую позицию, но всегда сначала возвращайтесь на дно. Как заставить мою анимацию продвигаться с текущей позиции каждый раз?

ЗАДАЧА
Я хочу, чтобы моя анимация выдвигалась на 120 пикселей от текущей новой позиции и повторялась после десяти.

ПРОБЛЕМА
Анимация сбрасывается на дно каждый раз перед продвижением. Я не знаю, если это проблема Tweener, как я настроил свой цикл или что-то не связанное. Если вы можете дать мне пример того, как изменить этот код, я был бы признателен.

альтернативный текст http://www.ashcraftband.com/myspace/videodnd/tweener.jpg

NumbersView.as 'код работает, но в замешательстве, как описано' 

package   
{ 
    import flash.display.DisplayObject; 
    import flash.display.MovieClip; 
    import flash.utils.Dictionary; 
    import flash.events.Event; 
    import caurina.transitions.Tweener; 

    public class NumbersView extends MovieClip 
    { 
        private var _listItems:Array; 
        private var previousNums:Array; 
        private const numHeight:int = 120; 

        public function NumbersView()  
        { 
            _listItems = new Array(); 
            previousNums = new Array(); 
            //Tweener.init();

            var item:NumberImage; 
            for (var i:Number = 0; i < 9; i++) { 
                item = new NumberImage(); 
                addChild(item); 
                item.x = i * item.width; 
                _listItems.push(item); 
            } 
        } 

        public function setTime($number:String):void { 
            var nums:Array = $number.split(""); 
            //trace("$number = " + $number);
            for (var i:Number = 0; i < nums.length; i++) { 
                if (nums[i] == previousNums[i]) continue; 
                Tweener.removeTweens(_listItems[i]);    

                //newY:int = -numHeight;
                var newY:int = int(nums[i]) * -numHeight;
                trace("newY = " + newY);
                trace("currY = " + _listItems[i].y);                
                if (_listItems[i].y < 0) _listItems[i].y = numHeight; 
                Tweener.addTween(_listItems[i], { y:newY, time:3 } ); 
            } 
            previousNums = nums; 
        } 
    } 
}

альтернативный текст http://www.ashcraftband.com/myspace/videodnd/tweener_.jpg

Tweener http://hosted.zeh.com.br/tweener/docs/en-us/

1 Ответ

0 голосов
/ 17 марта 2010

Я как бы смог получить ваш код для анимации элементов, и я увидел, что каждый раз, когда анимированные элементы перезапускались с их позиции, вот что я изменил, чтобы заставить их двигаться вверх от того места, где они в данный момент расположены: *

оригинал: 

if (_listItems[i].y < 0) _listItems[i].y = numHeight;
Tweener.addTween(_listItems[i], { y:newY, time:3 } );

изменено на: 

//if (_listItems[i].y < 0) _listItems[i].y = numHeight; //get rid of this line
Tweener.addTween(_listItems[i], { y:_listItems[i].y+newY, time:3 } );

Для зацикливания вы можете использовать таймер, вот что я собрал в качестве примера для вас. Возможно, он не идеален, но, надеюсь, даст вам представление о том, что вы хотите, чтобы он делал: 

package   
{ 
    import flash.display.DisplayObject; 
    import flash.display.MovieClip; 
    import flash.utils.Dictionary; 
    import flash.events.Event; 
    import flash.events.TimerEvent;
    import caurina.transitions.Tweener; 
    import flash.utils.Timer;

public class NumbersView extends MovieClip 
{ 
    private var _listItems:Array; 
    private var previousNums:Array; 
    private const numHeight:int = 120; 
    var t:Timer;

    public function NumbersView()  
    { 
        _listItems = new Array(); 
        previousNums = new Array(); 
        //Tweener.init();

        var item:NumberImage; 
        for (var i:Number = 0; i < 9; i++) { 
            item = new NumberImage(); 
            addChild(item); 
            item.x = i * item.width; 
            _listItems.push(item); 
        }

        t = new Timer( 1000 ) //1000ms = 1 second intervals
        t.addEventListener(TimerEvent.TIMER, onTimer);
        t.start();

    } 

    public function onTimer( e:TimerEvent):void {

        //this will run every 10th time firing
        if( t.currentCount % 10 == 0 ) {
            //do something to reset the listItems
            for (var i:Number = 0; i < _listItems.length; i++) { 
                _listItems[i].y = numHeight;
            }
        }

        //do your setTime function, I just randomly called it with random numbers
        setTime(Math.round(Math.random()*234567).toString());
    }

    public function setTime(number:String):void { 
        var nums:Array = number.split(""); 
        trace("$number = " + number);
        for (var i:Number = 0; i < nums.length; i++) { 
            if (nums[i] == previousNums[i]) continue; 
            Tweener.removeTweens(_listItems[i]);    

            //newY:int = -numHeight;
            var newY:int = int(nums[i]) * -numHeight;
            trace("newY = " + newY);
            trace("currY = " + _listItems[i].y);                

            Tweener.addTween(_listItems[i], { y:_listItems[i].y+newY, time:3 } ); 
        } 
        previousNums = nums; 
    } 
} 
}
...