Как получить полное имя владельца почтового файла в Lotus Notes

Question

Если у меня есть имя почтового файла и сервер, как мне получить полное имя пользователя, которому оно соответствует, в форме "CN = xxx / O = yyy" с использованием LotusScript?

Для начала у меня есть имя пользователя пользователя - часть перед @ в электронном письме: т.е. user1@example.com

Я также знаю сервер, на котором зарегистрирован этот пользователь, поэтому я использую Registration.GetUserInfo следующим образом:

Dim reg as New NotesRegistration
reg.RegistrationServer = "CN=myserver/O=mydomain"
Call reg.GetUserInfo("user1", mailserver$, mailfile$)

Вопрос: как из этих данных я могу получить полное имя пользователя?

Answer 1

Вот краткая реализация предложения Jonesys:

Function getMailFileUser(mailserver As String, mailfile As String) As String
    On Error Goto errorthrower  
    Dim session As New notessession

    Dim dd As NotesDatabase
    Forall candidate_dd In session.AddressBooks
        If candidate_dd.Server<>"" And candidate_dd.IsPublicAddressBook Then
            Set dd = candidate_dd
            Exit Forall
        End If
    End Forall 
    If dd Is Nothing Then Error 1978,"Failed to find Domino Directory"
    If Not dd.IsOpen Then Call dd.Open("","")


    Dim userdocs As NotesDocumentCollection
    Set userdocs = dd.Search({form="Person" & }& _
    {@name([CANONICALIZE];MailServer)=@name([CANONICALIZE];"} & mailserver & {") & } &_
    {MailFile="} & mailfile & {"},Nothing,1)

    Dim userdoc As NotesDocument
    Set userdoc = userdocs.GetFirstDocument
    If Not userdoc Is Nothing Then
        getMailFileUser = userdoc.FullName(0)       
    Else
        getMailFileUser=""
    End If

    Exit Function
ErrorThrower:
    Error Err, Error & Chr(13) + "Module: " & Cstr( Getthreadinfo(1) ) & ", Line: " & Cstr( Erl )
End Function

Несколько слов предостережения:

• CANONICALIZE выбирает свои значения из текущего идентификатора, а не из каталога домино - входные данные mailserver должны быть в сокращенной или канонической форме, чтобы это работало.
• Поле MailFile может включать или не включать расширение .nsf.
• Я не думаю, что имя файла чувствительно к регистру в Windows, но оно может быть на других платформах.

Если вам нужно часто выполнять эти поиски, возможно, наиболее эффективным решением является вычисляемая таблица поиска или представление в Domino Directory.

Answer 2

Если у вас есть имя почтового файла, почему бы не выполнить поиск в NAB, используя его в качестве ключа, и получить полное имя таким образом?

Answer 3

Я закончил с этим решением (как я знаю, какой сервер AddressBook для пользователя):

macro$ = { @DbLookup( "" ; "} & regServer & _
         {" : "names.nsf" ; "($Users)" ; "} & shortName & {" ; "FullName" ) }

Dim namelist As Variant

namelist = Evaluate ( macro$ )

commonName = namelist(0)

Answer 4

Если у вас есть интернет-адрес, вы можете просто использовать класс NotesName.

Dim s As New NotesSession
Dim userName As NotesName
Dim canonicalName as String

Set userName = s.CreateName("user@yourdomain.com")
'You can use the previous line or the next line to get the NotesName object
'Set userName = new NotesName("user@yourdomain.com")

canonicalName = userName.Canonical