При каких обстоятельствах переменные экземпляра объявляются как '_var' в 'use fields' private? - PullRequest
Новая
       34

При каких обстоятельствах переменные экземпляра объявляются как '_var' в 'use fields' private?

4 голосов
/ 09 июня 2010

Я пытаюсь понять поведение прагмы fields, которую я нахожу плохо документированной , в отношении полей с префиксом подчеркивания.Вот что говорит об этом документация:

Имена полей, начинающиеся с символа подчеркивания, делаются закрытыми для класса и не видны подклассам.Унаследованные поля могут быть переопределены, но при использовании вместе с ключом -w будет выдано предупреждение.

Это не согласуется с его фактическим поведением, согласно моему тесту ниже.Поля с префиксом _ не только видимы внутри подкласса, они также видны и во внешних классах (если я не понимаю, что означает «видимый»).Кроме того, прямой доступ к ограниченному хешу работает нормально.

Где можно найти больше информации о поведении fields прагмы, если не считать исходный код? 

{
    package Foo;
    use strict;
    use warnings;
    use fields qw/a _b __c/;

    sub new {
        my ( $class ) = @_;
        my Foo $self = fields::new($class);
        $self->a = 1; $self->b = 2; $self->c = 3;
        return $self;
    }

    sub a : lvalue { shift->{a}   }
    sub b : lvalue { shift->{_b}  }
    sub c : lvalue { shift->{__c} }
}
{
    package Bar;
    use base 'Foo';
    use strict;
    use warnings;
    use Data::Dumper;

    my $o = Bar->new;
    print Dumper $o; ##$VAR1 = bless({'_b' => 2, '__c' => 3, 'a' => 1}, 'Foo');

    $o->a = 4; $o->b = 5; $o->c = 6;
    print Dumper $o; ##$VAR1 = bless({'_b' => 5, '__c' => 6, 'a' => 4}, 'Foo');

    $o->{a} = 7; $o->{_b} = 8; $o->{__c} = 9;
    print Dumper $o; ##$VAR1 = bless({'_b' => 8, '__c' => 9, 'a' => 7}, 'Foo');
}

1 Ответ

7 голосов
/ 09 июня 2010

По совпадению, у меня есть тестовый скрипт в ~/codescraps/fields/test.pl, датированный два года назад, когда я экспериментировал с ответом точно на этот же вопрос. :) 

#!/usr/bin/perl

use strict;
use warnings;

use Data::Dumper;

{
   package Foo;
   use fields qw(foo bar _Foo_private);
   use private qw(_really_private);
   sub new {
       my Foo $self = shift;
       unless (ref $self) {
           $self = fields::new($self);
           $self->{_Foo_private} = "this is Foo's secret";
       }
       $self->{foo} = 10;
       $self->{bar} = 20;
       return $self;
   }
}

my $foo = Foo->new;
$foo->{foo} = 42;

# this will generate an error: field does not exist
#$foo->{zap} = 42;

print "_Foo_private: " . $foo->{_Foo_private} . "\n";
$foo->{_Foo_private} = 1;
print "_Foo_private: " . $foo->{_Foo_private} . "\n";

print "_really_private: " . $foo->{_really_private} . "\n";
$foo->{_really_private} = 1;
print "_really_private: " . $foo->{_really_private} . "\n";

print Dumper($foo);

# subclassing
{
   package Bar;
   use base 'Foo';
   use fields qw(baz _Bar_private);        # these fields not shared with Foo
   sub new {
       my $class = shift;
       my $self = fields::new($class);
       $self->SUPER::new();                # init base fields
       $self->{baz} = 10;                  # init own fields
       $self->{_Bar_private} = "this is Bar's secret";
       return $self;
   }
}

my $bar = Bar->new;
# these work fine
$bar->{foo} = 1;
$bar->{bar} = 1;
$bar->{_Bar_private} = 1;

# this will not work - underscored fields are not visible to children
$bar->{_Foo_private} = 1;

И когда я запускаю ваш код, я получаю сообщение об ошибке: 

No such pseudo-hash field "_b" at test2.pl line 16.

(строка 16 - это определение для подпункта b.) На какой архитектуре вы это используете? Объекты, использующие прагму полей, не являются простыми благословенными хеш-ссылками - они являются благословенными массивами, например, когда я изменяю ваш конструктор, чтобы он выглядел так: 

sub new {
    my ( $class ) = @_;
    my Foo $self = fields::new($class);
    $self->{a} = 1; $self->{_b} = 2; $self->{__c} = 3;
    print "I look like: ", Data::Dumper::Dumper($self);
    return $self;
}

Понятно: 

I look like: $VAR1 = bless( [
                 bless( {
                          'a' => 1
                        }, 'pseudohash' ),
                 1,
                 2,
                 3
               ], 'Bar' );

Как постскриптум, я чувствую себя обязанным указать, что прагма полей и прагма base , которые с ней связаны, устарели, и настоятельно рекомендуется избегать использования их. В настоящее время, если вы хотите создать хороший модуль OO с аксессорами, можно использовать Class :: Accessor или перейти непосредственно к Moose .

...