Как я могу увидеть, кто вызвал действие в Delphi?

Question

Когда действие даже срабатывает, «отправитель» всегда является самим действием.Обычно это наиболее полезно, но возможно ли как-то выяснить, кто вызвал событие onexecute действия?

Пример

Допустим, у вас есть форма со следующим:

• 2 кнопки, которые называются Button1 и Button2
• 1 TAction вызывается actDoStuff

Обе кнопки назначены одинаковому действию.Можно ли показать, какую кнопку я нажал?

Example.dfm

object Form1: TForm1
  object Button1: TButton
    Action = actDoStuff
  end
  object Button2: TButton
    Action = actDoStuff
    Left = 100
  end
  object actDoStuff: TAction
    Caption = 'Do Stuff'
    OnExecute = actDoStuffExecute
  end
end

Example.pas

unit Example;
interface
uses Windows, Classes, Forms, Dialogs, Controls, ActnList, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    actDoStuff: TAction;
    procedure actDoStuffExecute(Sender: TObject);
  end;

var
  Form1: TForm1;

implementation    
{$R *.dfm}

procedure TForm1.actDoStuffExecute(Sender: TObject);
begin
  ShowMessage('Button X was clicked');
end;

end.

Единственное решение, которое я вижу на данный момент, состоит в том, чтобы не использовать свойство action для кнопок, но иметь обработчик событий для каждой кнопки и вызывать оттуда actDoStuffExecute (), но этот вид бросает вызов всей цели использования действий в первомplace.

Я не хочу иметь отдельное действие для каждого отдельного элемента управления.Приведенный выше пример является упрощенной версией проблемы, с которой я сталкиваюсь.У меня есть меню с переменным количеством пунктов меню (имен файлов), и каждый пункт меню в основном должен делать то же самое, за исключением загрузки другого файла.Иметь действия для каждого пункта меню было бы немного глупо.

Answer 1

Попробуйте использовать свойство ActionComponent :

Хранит клиентский компонент, который вызвал выполнение этого действия.

Используйте ActionComponent , чтобы определить, какой клиентский компонент вызвал выполнение этого действия. Например, проверьте ActionComponent из обработчика событий OnExecute , если вам нужно знать, какое действие пользователя вызвало это действие.

Когда пользователь щелкает клиентский элемент управления, этот клиент устанавливает ActionComponent перед вызовом действия Выполнение метода. После выполнения действия оно сбрасывает ActionComponent на ноль.

Например:

  ShowMessage( (Sender as TAction).ActionComponent.Name );

Используя это, я получаю «Button1» и «Button2», когда я нажимаю первую и вторую кнопку соответственно.

Answer 2

Знание того, какая кнопка активировала действие, идет вразрез с точкой использования действий - действие может быть вызвано нажатием кнопки, щелчком меню или любым количеством других действий пользователя.Существуют действия для унификации управления состоянием включения / выключения и обработки щелчков между кнопками и меню.

Если вы хотите узнать, какая кнопка активировала действие, потому что вы хотите выполнить немного другую операцию, или «изменить»иначе, возможно, TAction не является правильным решением для того, что вы хотите сделать.

Answer 3

Вместо действий просто используйте событие щелчка.Установите все кнопки для использования одного и того же обработчика событий.В идеале, НЕ по имени первой кнопки (вы можете переименовать ее).

Вот код:

Procedure TMyForm.DestinationButtonClickHandlerThing(Sender: TObject); 
begin
  if Sender = Btn_ViewIt then
  begin
    // View It
  end
  else if Sender = Btn_FaxIt then
  begin
    // Fax It
  end
  else if Sender = Btn_ScrapIt then
  begin
    // Scrap It
  end
  else 
    ....   // error
   ...
end;

Answer 4

В некоторых ситуациях одно и то же действие должно применяться к аналогичным элементам управления.Проблема с

ShowMessage( (Sender as TAction).ActionComponent.Name );

заключается в том, что когда действие вызывается всплывающим меню, скажем, вы получаете имя всплывающего меню.Вы можете использовать:

procedure TMyForm.actMyActionExecute(Sender: TObject);
var
  LMyControl: TMyControl;
begin
  if Screen.ActiveControl.Name = 'MyControl1' then
    LMyControl = Sender as TMyControl
  else
    Exit;
  // Use the local variable for whatever needed
end;

Answer 5

установите для тега кнопок 1, 2, ... и т. Д., А затем:

procedure TForm1.FormCreate(Sender: TObject);
begin
  Button1.OnClick := ButtonClick;
  Button2.OnClick := ButtonClick;
end;

procedure TForm1.ButtonClick(Sender: TObject);
begin
  if Sender is TButton then
  begin
    Caption := 'Button: ' + IntToStr(TButton(Sender).Tag);
  end;  
end;

Answer 6

Хорошо, пока что я думаю, что нашел работоспособное решение ..

Я могу использовать для всех элементов управления одно и то же действие; Мне просто нужно переопределить их обработчик событий OnClick, и мне просто нужен один обработчик для всех из них.

Мне все еще интересно узнать, возможно ли выяснить, какой элемент управления вызвал действие, но для моего текущего приложения я использую решение, похожее на код ниже:

unit Example;

interface

uses
  Windows, Classes, Forms, Dialogs, Controls, ActnList, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    actDoStuff: TAction;
    procedure actDoStuffExecute(Sender: TObject);
    procedure ButtonClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.actDoStuffExecute(Sender: TObject);
begin
  ShowMessage('Button '+TControl(Sender).Name +' was clicked')
end;

procedure TForm1.ButtonClick(Sender: TObject);
begin
  actDoStuffExecute(Sender)
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Button1.OnClick := ButtonClick;
  Button2.OnClick := ButtonClick
end;

end.