Как я могу перегрузить конструкторы Moose? - PullRequest
Новая
       10

Как я могу перегрузить конструкторы Moose?

5 голосов
/ 23 октября 2010

Извините за жаргон Java, но как я могу перегрузить конструкторы Moose?

Предположим, я представляю сегмент.Я могу либо взять начальную точку и точку, либо начальную точку и длину, либо конечную точку и длину.

Как разрешить использование таких альтернативных методов построения?

Ответы [ 2 ]

11 голосов
/ 23 октября 2010

Вам не нужно переопределять new. Вы можете поставить свои собственные BUILD: 

#!/usr/bin/perl

package My::Segment;

use Moose;
use namespace::autoclean;
use Carp qw( confess );

has 'start' => (is => 'ro', isa => 'Num',
    predicate => 'has_start', writer => '_set_start',
);

has 'end' => (is => 'ro', isa => 'Num',
    predicate => 'has_end', writer => '_set_end',
);

has 'length' => (is => 'ro', isa => 'Num',
    predicate => 'has_length', writer => '_set_length',
);

sub BUILD {
    my $self = shift;

    $self->has_start and $self->has_end and $self->length and do {
        return if $self->length == $self->end - $self->start;
        confess "Inconsistent start, end and length";
    };

    $self->has_start and $self->has_end and do {
        $self->_set_length($self->end - $self->start);
        return;
    };
    $self->has_start and $self->has_length and do {
        $self->_set_end($self->start + $self->length);
        return;
    };
    $self->has_end and $self->has_length and do {
        $self->_set_start($self->end - $self->length);
        return;
    };
    confess "At least two of start, end or length must be supplied";
}

__PACKAGE__->meta->make_immutable;

package main;
use YAML;

my $x = My::Segment->new(start => 0, length => 3);
my $y = My::Segment->new(start => 1, end => 4);
my $z = My::Segment->new(end => 5, length => 3);

print Dump($_) for $x, $y, $z;

my $w = My::Segment->new(start => 0, end => 0, length => 1);
3 голосов
/ 24 октября 2010

Ответ Синана BUILD, вероятно, является самым разумным и простым решением.Использование BUILDARGS в качестве упомянутого Дэйва также является разумным решением.

Мне показалось, что стоит упомянуть, что можно также использовать Type Coercions.Для данного класса: 

class LineSegment { 
  has [qw(startX startY endX endY)] => ( 
         isa => 'Num', 
         is  => 'ro', 
         required => 1 
  );
}

Вы можете использовать набор принуждений, например, так: 

class_type 'LineSegment';

subtype StartLength 
     => as Hashref 
     => where { exists $_->{startX} && $_->{startY} && $_->{length} };

subtype EndLength 
     => as Hashref 
     => where { exists $_->{endX} && $_->{endY} && $_->{length} };    

coerce LineSegment 
     => from StartLength 
     => via { my ($endX, $endY) = calc_end($_); 
              LineSegment->new(
                   startX => $_->{startX}, 
                   startY => $_->{startY},
                   endX => $endX,
                   endY => $endY,
            )};
coerce LineSegment 
     => from EndLength 
     => via { my ($startX, $startY) = calc_start($_); 
              LineSegment->new(
                   startX => $startX, 
                   startY => $startY,
                   endX => $_->{endX},
                   endY => $_->{endY},
            )};

Тогда в вашем коде: 

 use Moose::Util::TypeConstraints;
 find_type_constraint('LineSegment')->coerce({
       startX => $x, 
       startY => $y, 
       length => $length
 });

Хотя, возможно, избыточноВ этом примере есть несколько раз, когда принуждение является элегантным решением.Например, если у вас есть существующий класс LineSegment, к которому вы не хотите добавлять атрибут length (хотя BUILDARGS также будет работать там хорошо)

...