Как получить основной объем в Windows XP? - PullRequest
Новая
       7

Как получить основной объем в Windows XP?

5 голосов
/ 22 декабря 2010

В Windows XP, с Delphi, как получить мастер-громкость?

Я знаю, что могу установить и уменьшить отправку нажатий клавиш с помощью keybd_event(VK_VOLUME_UP, 1, 0, 0); и keybd_event(VK_VOLUME_DOWN, 1, 0, 0);, но я не знаю, какчтобы получить фактическое значение объема.

1 Ответ

3 голосов
/ 22 декабря 2010

Ниже приведена небольшая модификация примера кода, найденного здесь (зачислено там - Томас Штутц). Пример там устанавливает громкость микрофона. Я просто изменил тип компонента - назначение динамика вместо источника микрофона и заменил mixerSetControlDetails на mixerGetControlDetails, и, конечно, превратил сеттер в геттер. На тех немногих системах, которые я тестировал здесь (XPSp3, XPSp2, W2K, 98), это похоже на работу. Возвращение функции - это динамик из первого (по умолчанию) микшера - значение 0-65535, «ShowMessage» в обработчике кнопок меняет его в процентах. Но не спрашивайте меня больше об этом, у меня действительно нет опыта работы с API микшера. Вместо этого обратитесь здесь f.i., хотя старая статья действительно казалась мне всеобъемлющей. 

function GetSpeakerVolume(var bValue: Word): Boolean;
var                          {0..65535}
  hMix: HMIXER;
  mxlc: MIXERLINECONTROLS;
  mxcd: TMIXERCONTROLDETAILS;
  vol: TMIXERCONTROLDETAILS_UNSIGNED;
  mxc: MIXERCONTROL;
  mxl: TMixerLine;
  intRet: Integer;
  nMixerDevs: Integer;
begin
  Result := False;

  // Check if Mixer is available
  nMixerDevs := mixerGetNumDevs();
  if (nMixerDevs < 1) then
    Exit;

  // open the mixer
  intRet := mixerOpen(@hMix, 0, 0, 0, 0);
  if intRet = MMSYSERR_NOERROR then
  begin
    mxl.dwComponentType := MIXERLINE_COMPONENTTYPE_DST_SPEAKERS;
    mxl.cbStruct := SizeOf(mxl);

    // get line info
    intRet := mixerGetLineInfo(hMix, @mxl, MIXER_GETLINEINFOF_COMPONENTTYPE);

    if intRet = MMSYSERR_NOERROR then
    begin
      ZeroMemory(@mxlc, SizeOf(mxlc));
      mxlc.cbStruct := SizeOf(mxlc);
      mxlc.dwLineID := mxl.dwLineID;
      mxlc.dwControlType := MIXERCONTROL_CONTROLTYPE_VOLUME;
      mxlc.cControls := 1;
      mxlc.cbmxctrl := SizeOf(mxc);

      mxlc.pamxctrl := @mxc;
      intRet := mixerGetLineControls(hMix, @mxlc, MIXER_GETLINECONTROLSF_ONEBYTYPE);

      if intRet = MMSYSERR_NOERROR then
      begin
        ZeroMemory(@mxcd, SizeOf(mxcd));
        mxcd.dwControlID := mxc.dwControlID;
        mxcd.cbStruct := SizeOf(mxcd);
        mxcd.cMultipleItems := 0;
        mxcd.cbDetails := SizeOf(vol);
        mxcd.paDetails := @vol;
        mxcd.cChannels := 1;

        intRet := mixerGetControlDetails(hMix, @mxcd, MIXER_GETCONTROLDETAILSF_VALUE);
        if intRet <> MMSYSERR_NOERROR then
          ShowMessage('GetControlDetails Error')
        else begin
          bValue := vol.dwValue;
          Result := True;
        end;
      end
      else
        ShowMessage('GetLineInfo Error');
    end;
    intRet := mixerClose(hMix);
  end;
end;


procedure TForm1.Button1Click(Sender: TObject);
var
  Vol: Word;
begin
  if GetSpeakerVolume(Vol) then
    ShowMessage(IntToStr(Round(Vol * 100 / 65535)));
end;
...