Hook Script для отключения Break Lock в черепахе SVN - PullRequest
Новая
       24

Hook Script для отключения Break Lock в черепахе SVN

1 голос
/ 22 декабря 2010

Мне нужно отключить параметр блокировки взлома в tortoiseSVN для пользователей.У меня уже есть Pre-lock.BAT HOOK, который блокирует опцию блокировки кражи.Может кто-нибудь предоставить мне скрипт, который блокирует как блокировку, так и блокировку.Пожалуйста, ответьте ...

У меня есть скрипт Hook (он блокирует только блокировку кражи, а не блокировку взлома) 

@echo off

set SVN_REPOS=%1
set SVN_PATH=%2
set SVN_USER=%3

set lock_owner = ""
set lock_message = ""

REM Skip one row of output, take second token, and delimiter is " "
for /f "skip=1 tokens=2" %%U in ('svnlook lock %SVN_REPOS% %SVN_PATH%') do (
  set lock_owner=%%U
  goto :check_owner
)

:check_owner
if "%lock_owner%" == "" exit 0
if "%SVN_USER%" == "ADMIN" exit 0

for /f "skip=5 tokens=*" %%U in ('svnlook lock %SVN_REPOS% %SVN_PATH%') do (
  set lock_message=%%U
)

@echo on
if not "%lock_message%" == "" echo Lock message: %lock_message% 1>&2
echo Sorry %SVN_USER%. Error: %SVN_PATH% locked by %lock_owner%. 1>&2
exit 1

Ответы [ 3 ]

1 голос
/ 09 августа 2011 
@echo off

REM [1] REPOS-PATH   (the path to this repository)
REM [2] PATH         (the path in the repository about to be locked)
REM [3] USER         (the user creating the lock)
REM [4] COMMENT      (the comment of the lock)
REM [5] STEAL-LOCK   (1 if the user is trying to steal the lock, else 0)

setlocal
::svn对代码资源库路径与文件路径里的右小括号敏感，需要对其转义
::代码资源库路径
set repos=%1 
set "repos=%repos:)=^)%"
::当前文件路径
set repPath=%2
set "repPath=%repPath:)=^)%"
set userName=%3
set isSteal=%5

rem NO_STEALING
::如果没有被锁定，则直接跳走结束处理
if /I '1'=='%isSteal%' goto NO_STEALING
REM echo aaa >>d:\log.txt
REM echo repos = %repos% >>d:\log.txt
REM echo repPath = %repPath% >>d:\log.txt
REM echo userName = %userName% >>d:\log.txt
rem if the path has been locked, find the Owner.
::这里是处理重点
::通过svnlook lock %repos% %repPath%,命令获取锁信息，例如：
::  UUID Token: opaquelocktoken:1707b1a0-8dd1-a94e-87d2-6569a115cd5c
::  Owner: ljz
::  Created: 2011-08-08 21:05:31 +0800 (周一, 08 八月 2011)
::  Expires:
::  Comment (1 line):
::通过findstr /r /n ".",将所有行的前面加上行号，前返回所有行，例如：
::  1:UUID Token: opaquelocktoken:1707b1a0-8dd1-a94e-87d2-6569a115cd5c
::  2:Owner: ljz
::  3:Created: 2011-08-08 21:05:31 +0800 (周一, 08 八月 2011)
::  4:Expires:
::  5:Comment (1 line):
::通过tokens=1,2,3 delims=: ,以:号与空格作为分隔符，将上述每一行分隔，并将前三段分别装入变量%%i，%%j,%%k
::通过if %%i == 2 set LockedName=%%k,把第二行分隔后的第三段装入变量LockedName，在这里，就是ljz
for /f "tokens=1,2,3 delims=: " %%i in ('svnlook lock %repos% %repPath% ^|findstr /r /n "."') do (
        if %%i == 2 set LockedName=%%k
        )

rem If we get no result from svnlook, there's no lock, allow the lock to happen.
::如果没有获取到锁定信息，则直接跳走结束处理
if not defined LockedName goto OK_EXIT

rem If the person locking matches the lock's owner, allow the lock to happen.
rem But this one won't effect, the SVN don't care if the person matchs, they just don't allow relock.
REM echo userName = %userName% >>d:\log.txt
REM echo LockedName = %LockedName% >>d:\log.txt
::如果锁定人与当前用户同名，则直接跳走结束处理
if /I '%LockedName%'=='%userName%' goto OK_EXIT

rem Otherwise, we've got an owner mismatch, so return failure:
:WRONG_PERSON
echo the path has been locked by %LockedName%, Pls contact %LockedName% to unlock it.>&2 
goto ERROR_EXIT 
:NO_STEALING
echo Stealing lock is not allowed at this server.>&2
:ERROR_EXIT
endlocal
exit 1
:OK_EXIT
endlocal
exit 0
1 голос
/ 24 марта 2011

На тот случай, если кому-то понадобится эта информация, есть другой хук (предварительная разблокировка), используемый блокировкой разрыва.Вы можете использовать тот же сценарий для отключения блокировки взлома.

Cheers, Arminio

0 голосов
/ 03 июля 2019

Вот более короткая версия, основанная на том, что ljzforever уже опубликовал:

Отключить блокировку кражи (pre-lock.bat): 

@echo off
REM https://www.visualsvn.com/support/svnbook/ref/reposhooks/pre-lock/
rem Repository path
set SVN_REPOS=%1
rem Versioned path that is to be locked
set SVN_PATH=%2
rem Authenticated username of the person attempting the lock
set SVN_USER=%3
rem Comment provided when the lock was created
set SVN_COMMENT=%4
REM 1 if the user is attempting to steal an existing lock; 0 otherwise
set SVN_STEAL=%5


if "%SVN_STEAL%" == "1" (
@echo on
echo THE STEAL LOCK OPTION IS DISABLED, PLEASE CONTACT ADMIN. 1>&2
exit 1 
)

Отключить блокировку разблокировки (pre-unlock.bat): 

@echo off
REM https://www.visualsvn.com/support/svnbook/ref/reposhooks/pre-unlock/
rem Repository path
set SVN_REPOS=%1
rem Versioned path which is to be unlocked
set SVN_PATH=%2
rem Authenticated username of the person attempting the unlock
set SVN_USER=%3
rem Lock token associated with the lock which is to be removed
set SVN_LOCK_TOKEN=%4
REM 1 if the user is attempting to break the lock; 0 otherwise
set SVN_BREAK=%5


if "%SVN_BREAK%" == "1" (
@echo on
echo THE BREAK LOCK OPTION IS DISABLED, PLEASE CONTACT ADMIN. 1>&2
exit 1 
)
...