OpenLink Virtuoso: обнаружение, если два узла соединены на определенном расстоянии - PullRequest
Новая
       12

OpenLink Virtuoso: обнаружение, если два узла соединены на определенном расстоянии

2 голосов
/ 12 октября 2010

Как найти расстояние между 2 узлами в графике с помощью Virtuoso? Я прочитал документацию о транзитивности, но они ограничивают вас одним предикатом, например ::1001 

SELECT ?link ?g ?step ?path
WHERE
{
  {
    SELECT ?s ?o ?g
    WHERE
      {
        graph ?g {?s foaf:knows ?o }
      }
  } OPTION (TRANSITIVE, t_distinct, t_in(?s), t_out(?o), t_no_cycles, T_shortest_only,
  t_step (?s) as ?link, t_step ('path_id') as ?path, t_step ('step_no') as ?step, t_direction 3) .
  FILTER (?s= <http://www.w3.org/People/Berners-Lee/card#i>
  && ?o = <http://www.advogato.org/person/mparaz/foaf.rdf#me>)
}
LIMIT 20

Только обходы foaf:knows, а не любой тип предиката. Как я могу распространить это на «любой предикат»? Мне не нужен фактический путь, просто истина / ложь (запрос ASK). Изменение foaf: знает, что? P кажется излишним.

В настоящее время я выполняю набор рекурсивных ASK, чтобы выяснить, связаны ли два узла на определенном расстоянии, но это не кажется эффективным.

Ответы [ 2 ]

4 голосов
/ 18 октября 2010

Вы должны иметь возможность использовать ?p вместо foaf:knows в своем запросе, чтобы определить, существует ли путь между узлами.Например: 

SELECT ?link ?g ?step ?path
   WHERE
   {
     {
       SELECT ?s ?o ?g
       WHERE
         {
           graph ?g {?s ?p ?o }
         }
     } OPTION (TRANSITIVE, t_distinct, t_in(?s), t_out(?o), t_no_cycles, T_shortest_only,
     t_step (?s) as ?link, t_step ('path_id') as ?path, t_step ('step_no') as ?step, t_direction 3) .
     FILTER (?s= <http://www.w3.org/People/Berners-Lee/card#i>
     && ?o = <http://www.advogato.org/person/mparaz/foaf.rdf#me>)
   }
   LIMIT 20
1 голос
/ 06 марта 2014

Вот подход, который работает, если существует не более одного пути между интересующими вас узлами. Если у вас есть такие данные (обратите внимание, что есть разные свойства, соединяющие ресурсы): 

@prefix : <https://stackoverflow.com/q/3914522/1281433/>

:a :p :b .
:b :q :c .
:c :r :d .

Затем запрос, подобный следующему, находит расстояние между каждой парой узлов.Путь свойства (:|!:) состоит из свойства, которое является либо :, либо чем-то отличным от : (т. Е. Чем угодно).Таким образом, (:|!:)* - ноль или более вхождений любого свойства;это подстановочный путь.(Используемая здесь методика более подробно описана в Можно ли получить положение элемента в RDF-коллекции в SPARQL? .) 

prefix : <https://stackoverflow.com/q/3914522/1281433/>

select ?begin ?end (count(?mid)-1 as ?distance) where {
 ?begin (:|!:)* ?mid .
 ?mid (:|!:)* ?end .
}
group by ?begin ?end
order by ?begin ?end ?distance

--------------------------
| begin | end | distance |
==========================
| :a    | :a  | 0        |
| :a    | :b  | 1        |
| :a    | :c  | 2        |
| :a    | :d  | 3        |
| :b    | :b  | 0        |
| :b    | :c  | 1        |
| :b    | :d  | 2        |
| :c    | :c  | 0        |
| :c    | :d  | 1        |
| :d    | :d  | 0        |
--------------------------

Просто найтиЧтобы определить, существует ли путь между двумя узлами, который меньше определенной длины, вы используете запрос ask вместо select, фиксируете значения ?begin и ?end и скорее ограничиваете значение count(?mid)-1чем привязать его к ?distance.Например, есть ли путь от :a до :d длиной менее трех? 

prefix : <https://stackoverflow.com/q/3914522/1281433/>

ask {
 values (?begin ?end) { (:a :d) }
 ?begin (:|!:)* ?mid .
 ?mid (:|!:)* ?end .
}
group by ?begin ?end
having ( (count(?mid)-1 < 3 ) )

Ask => No

С другой стороны, существует путь от :a до :c сдлина менее 5: 

prefix : <https://stackoverflow.com/q/3914522/1281433/>

ask {
 values (?begin ?end) { (:a :c) }
 ?begin (:|!:)* ?mid .
 ?mid (:|!:)* ?end .
}
group by ?begin ?end
having ( (count(?mid)-1 < 5 ) )

Ask => Yes
...