переименовать элемент с помощью xslt

Question

У меня есть этот xml:

<pos:getPositionRouter xmlns:pos="positionNS">
   <positionID>
      <code>1</code>
   </positionID>
   <parameter>?</parameter>
</pos:getPositionRouter>

и я хочу переименовать элемент pos:getPositionRouter в x:getPosition, используя xslt:

<x:getPosition xmlns:x="newPositionNS">
   <positionID>
      <code>1</code>
   </positionID>
   <parameter>?</parameter>
</x:getPosition>

Это таблица, которую я придумал:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

 <xsl:output method="xml" omit-xml-declaration="yes" indent="yes" />

 <xsl:param name="old_namespace" />
 <xsl:param name="old_element_localname" />
 <xsl:param name="new_namespace" />
 <xsl:param name="new_element_localname" />


 <xsl:template match="@*|node()">
  <xsl:choose>
   <xsl:when test="(local-name() = $old_element_localname) and (namespace-uri() = $old_namespace)">
    <xsl:element name="{$new_element_localname}" namespace="{$new_namespace}">
     <xsl:apply-templates select="@*|node()"/>
    </xsl:element>
   </xsl:when>

   <!-- copy the rest as is -->
   <xsl:otherwise>
    <xsl:copy>
     <xsl:apply-templates select="@*|node()" />
    </xsl:copy>
   </xsl:otherwise>
  </xsl:choose>
 </xsl:template>

</xsl:stylesheet> 

Я вынужден использовать xalan в качестве процессора xslt, и вывод, к сожалению, таков:

<getPosition xmlns="newPositionNS">
   <positionID xmlns:pos="positionNS">
      <code>1</code>
   </positionID>
   <parameter xmlns:pos="positionNS">?</parameter>
</getPosition>

Пространство имен по умолчанию для элемента getPosition становится новым пространством имен, но дочерние элементы должны оставаться без пространства имен (xmlns="").

Может кто-то понять, почему?

Спасибо!

Answer 1

Эта таблица стилей:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:param name="old_namespace" select="'positionNS'"/>
    <xsl:param name="old_element_localname" select="'getPositionRouter'"/>
    <xsl:param name="new_namespace_prefix" select="'x'"/>
    <xsl:param name="new_namespace" select="'newPositionNS'"/>
    <xsl:param name="new_element_localname" select="'getPosition'" />
    <xsl:template match="*">
        <xsl:choose>
            <xsl:when test="local-name()=$old_element_localname and
                            namespace-uri()=$old_namespace">
                <xsl:element
                     name="{substring(concat($new_namespace_prefix,':'),
                                      1 div boolean($new_namespace_prefix))}{
                            $new_element_localname}"
                     namespace="{$new_namespace}">
                    <xsl:apply-templates select="@*|node()"/>
                </xsl:element>
            </xsl:when>
            <xsl:otherwise>
                <xsl:element name="{name()}">
                    <xsl:apply-templates select="@*|node()"/>
                </xsl:element>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    <xsl:template match="@*">
        <xsl:attribute name="{name()}">
            <xsl:value-of select="."/>
        </xsl:attribute>
    </xsl:template>
</xsl:stylesheet>

Выход:

<x:getPosition xmlns:x="newPositionNS">
    <positionID>
        <code>1</code>
    </positionID>
    <parameter>?</parameter>
</x:getPosition>

Примечание : если вы хотите определенный префикс, вы должны добавить его в QName. Если вы хотите удалить внутреннее пространство имен, вы не должны использовать xsl:copy в XSLT 1.0

Answer 2

I. Преобразование для этого без использования параметров действительно короткое и простое :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:pos="positionNS" xmlns:x="newPositionNS" >
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="pos:getPositionRouter">
  <xsl:element name="x:getPosition">
   <xsl:apply-templates/>
  </xsl:element>
 </xsl:template>

 <xsl:template match="*">
  <xsl:element name="{name()}">
   <xsl:copy-of select="namespace::*[not(name()='pos')]"/>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:element>
  <xsl:apply-templates/>
 </xsl:template>
</xsl:stylesheet>

применительно к предоставленному документу XML :

<pos:getPositionRouter xmlns:pos="positionNS">
   <positionID>
      <code>1</code>
   </positionID>
   <parameter>?</parameter>
</pos:getPositionRouter>

желаемый, правильный результат получается :

<x:getPosition xmlns:x="newPositionNS">
    <positionID>
        <code>1</code>1
    </positionID>
    <code>1</code>1
    <parameter>?</parameter>?
</x:getPosition>

II. Параметризованное преобразование немного сложнее :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pOldNamespace"  select="'positionNS'"/>
 <xsl:param name="pOldElementLocalname"  select="'getPositionRouter'"/>
 <xsl:param name="pNewNamespace"  select="'newPositionNS'"/>
 <xsl:param name="pNewElementLocalname"  select="'getPosition'"/>
 <xsl:param name="pNewElementPrefix"  select="'x'"/>

 <xsl:template match="*">
  <xsl:variable name="vReplacing" select=
  "local-name()=$pOldElementLocalname
  and
    namespace-uri()=$pOldNamespace"/>

  <xsl:variable name="vName">
  <xsl:choose>
   <xsl:when test="$vReplacing">
     <xsl:value-of select="concat($pNewElementPrefix, ':', local-name())"/>
    </xsl:when>
    <xsl:otherwise><xsl:value-of select="name()"/></xsl:otherwise>
  </xsl:choose>
  </xsl:variable>

  <xsl:variable name="vNamespace">
   <xsl:choose>
    <xsl:when test="$vReplacing">
     <xsl:value-of select="$pNewNamespace"/>
    </xsl:when>
    <xsl:otherwise>
     <xsl:value-of select="namespace-uri()"/>
    </xsl:otherwise>
   </xsl:choose>
  </xsl:variable>

  <xsl:element name="{$vName}" namespace="{$vNamespace}">
    <xsl:copy-of select="namespace::*[not(.=$pOldNamespace)]"/>
    <xsl:apply-templates select="node()|@*"/>
  </xsl:element>
 </xsl:template>
</xsl:stylesheet>