Как включить отключенный пункт контекстного меню, когда выбор происходит в графическом интерфейсе Perl Tk? - PullRequest
Новая
       46

Как включить отключенный пункт контекстного меню, когда выбор происходит в графическом интерфейсе Perl Tk?

2 голосов
/ 01 сентября 2010

Например, в следующем скрипте: 

use Tk;

my $mw = new MainWindow;
my $t  = $mw->Scrolled("Text")->pack;

my $popup = $mw->Menu(
    -menuitems => [
        [
            Button   => 'Copy Selected',
            -state   => "disabled",
            -command => sub {$t->clipboardColumnCopy}
        ],
    ]
);
$t->menu($popup);

MainLoop;

Как узнать, когда происходит выбор, чтобы я мог использовать следующий код 

$popup->entryconfigure(1, -state=>'normal');

для изменения состояния пункта меню?

ОБНОВЛЕНИЕ:

Большое спасибо @Chas и @gbacon:)

Думаю, возможно, я смогу также объединить два хороших ответа: 

$t->bind(
    "<Button1-ButtonRelease>",
    sub {
        local $@;
        my $state = defined eval { $t->SelectionGet } ? 
            "normal" : "disable";
        $popup->entryconfigure(1, -state => $state)
    }
);

Ответы [ 2 ]

2 голосов
/ 01 сентября 2010

Несколько изменений приводят к желаемому поведению.Приведенный ниже код отслеживает <ButtonPress-1>, что может отменить выбор и, если это так, отключить функцию копирования выбранногоДля <ButtonPress-3>, он включает пункт меню, если есть выбор. 

my $copySelectedLabel = "Copy Selected";
my $popup = $mw->Menu(
    -menuitems => [
        [
            Button   => $copySelectedLabel,
            -state   => "disabled",
            -command => sub {$t->clipboardColumnCopy}
        ],
    ]
);

sub maybeEnableCopySelected {
  local $@;
  $popup->entryconfigure($copySelectedLabel, -state => "normal")
    if defined eval { $t->SelectionGet };
}

sub maybeDisableCopySelected {
  local $@;
  $popup->entryconfigure($copySelectedLabel, -state => "disabled")
    unless defined eval { $t->SelectionGet };
}

$t->bind('<ButtonPress-1>' => \&maybeDisableCopySelected);
$t->bind('<ButtonPress-3>' => \&maybeEnableCopySelected);
$t->menu($popup);
2 голосов
/ 01 сентября 2010

Я не очень хорошо знаю Tk, но это ответ (но, возможно, не правильный): 

#!/usr/bin/perl

use strict;
use warnings;

use Tk;

my $mw = new MainWindow;
my $t  = $mw->Text->pack;


my $popup = $mw->Menu(
    -menuitems => [
        [ Button => 'Copy Selected', -state => "disabled", -command => sub {$t->clipboardColumnCopy} ],
    ]
);
$t->menu($popup);

$t->bind(
    "<Button1-ButtonRelease>",
    sub {
        my $text = $t->getSelected;
        if (length $text) {
            $popup->entryconfigure(1, -state => 'normal');
        } else {
            $popup->entryconfigure(1, -state => 'disabled');
        }
    }
);

MainLoop;
...