ANTLR: проблема дифференцирования унарных и бинарных операторов (например, знак минус) - PullRequest
Новая
       32

ANTLR: проблема дифференцирования унарных и бинарных операторов (например, знак минус)

8 голосов
/ 26 октября 2010

Я использую ANTLR (3.2) для анализа довольно простой грамматики. К сожалению, я столкнулся с небольшой проблемой. Возьмите следующее правило: 

exp
 : NUM
 | '(' expression OPERATOR expression ')' -> expression+
 | '(' (MINUS | '!') expression ')' -> expression
 ;

ОПЕРАТОР содержит тот же знак минуса ('-'), который определен для МИНУС. Теперь ANTLR, похоже, не может справиться с этими двумя правилами. Если я удаляю любой из них, все работает нормально.

Есть идеи?

1 Ответ

10 голосов
/ 26 октября 2010

Сделайте унарное выражение с наивысшим приоритетом. Я бы также использовал другой токен для унарного символа -, чтобы лучше отличить минус. Демо: 

grammar Exp;

options { 
  output=AST;
}

tokens {
  UNARY;
}

parse
  :  exp EOF
  ;

exp
  :  additionExp
  ;

additionExp
  :  multiplyExp ('+'^ multiplyExp | '-'^ multiplyExp)*
  ;

multiplyExp
  :  unaryExp ('*'^ unaryExp | '/'^ unaryExp)* 
  ;

unaryExp
  :  '-' atom -> ^(UNARY atom)
  |  '!' atom -> ^('!' atom)
  |  atom
  ;

atom
  :  '(' exp ')' -> exp
  |  Number      -> Number
  ;

Number : ('0'..'9')+ ('.' ('0'..'9')+)? ;

Spaces : (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;} ;

Быстрый тест с источником: 

3 * -4 + 7 / 6 * -(3 + -7 * (4 + !2))

произвел следующее AST:

alt text

...