XSLT 1.0 накопление, суммирование, умножение - PullRequest
Новая
       7

XSLT 1.0 накопление, суммирование, умножение

3 голосов
/ 24 декабря 2010

У меня есть небольшой фиксированный набор узлов: <a>, <b>, <c>, <d>. Каждый узел может иметь значение 1 или 0. Также каждый узел имеет вес: 1, 2, 3, 4 соответственно. Атрибуты узла не используются. Как можно суммировать значение каждого узла, умноженное на его вес, используя XSLT 1.0? Пример: 

<a>0</a>
<b>1</b>
<c>0</c>
<d>1</d>

Сумма: 6 

<a>1</a>
<b>1</b>
<c>0</c>
<d>0</d>

Сумма: 3 

<a>0</a>
<b>1</b>
<c>1</c>
<d>1</d>

Сумма: 9

Ответы [ 2 ]

3 голосов
/ 24 декабря 2010

Это преобразование XSLT 1.0 : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
  <xsl:call-template name="sumWeighted"/>
 </xsl:template>

 <xsl:template name="sumWeighted">
   <xsl:param name="pList" select="*"/>
   <xsl:param name="pIndex" select="1"/>
   <xsl:param name="pAccum" select="0"/>

   <xsl:choose>
    <xsl:when test="$pIndex > count($pList)">
     <xsl:value-of select="$pAccum"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:call-template name="sumWeighted">
        <xsl:with-param name="pList" select="$pList"/>
        <xsl:with-param name="pIndex"
             select="$pIndex+1"/>
        <xsl:with-param name="pAccum"
             select="$pAccum+$pList[$pIndex]*$pIndex"/>
      </xsl:call-template>
    </xsl:otherwise>
   </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

применительно к предоставленным документам XML : 

<t>
    <a>0</a>
    <b>1</b>
    <c>0</c>
    <d>1</d>
</t>


<t>
    <a>1</a>
    <b>1</b>
    <c>0</c>
    <d>0</d>
</t>

и 

<t>
    <a>0</a>
    <b>1</b>
    <c>1</c>
    <d>1</d>
</t>

дает желаемые результаты соответственно :

6

3

9

Ссылка

Если вы хотите испачкать руки сложными математическими вычислениями с использованием XSLT, посмотрите это:

http://fxsl.sourceforge.net/articles/xslCalculator/The%20FXSL%20Calculator.html

XPath 2.0 / XSLT 2.0 Solution :

Используйте только одну строку XPath 2.0: 

   sum(/*/*/(number()*position()))
3 голосов
/ 24 декабря 2010

Не очень элегантно, но вот что пришло мне в голову. 

<xsl:stylesheet
version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:my="my:my"
exclude-result-prefixes="my">
<xsl:output method="text"/>
<xsl:strip-space elements="*"/>

<my:node-weight>
    <node name="a" weight="1"/>
    <node name="b" weight="2"/>
    <node name="c" weight="3"/>
    <node name="d" weight="4"/>
</my:node-weight>

<xsl:template match="root">
    <xsl:apply-templates select="*[1]" mode="sum"/>
</xsl:template>

<xsl:template match="*" mode="sum">
    <xsl:param name="sumNumber" select="0"/>
    <xsl:variable name="thisWeight" select="document('')/*/my:node-weight/node[@name = local-name(current())]/@weight"/>
    <xsl:choose>
        <xsl:when test="following-sibling::*">
            <xsl:apply-templates select="following-sibling::*[1]" mode="sum">
                <xsl:with-param name="sumNumber" select="$sumNumber + $thisWeight * number()"/>
            </xsl:apply-templates>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$sumNumber + $thisWeight * number()"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

Применительно к следующим правильно оформленным документам: 

<root>
    <a>0</a>
    <b>1</b>
    <c>0</c>
    <d>1</d>
</root>

Результат равен 6

<root>
    <a>1</a>
    <b>1</b>
    <c>0</c>
    <d>0</d>
</root>

Результат 3

<root>
    <a>0</a>
    <b>1</b>
    <c>1</c>
    <d>1</d>
</root>

Результат 9

...