Как передать аргументы и вернуть значения с помощью обработчика XML :: Twig? - PullRequest
Новая
       6

Как передать аргументы и вернуть значения с помощью обработчика XML :: Twig?

5 голосов
/ 12 июля 2010

У меня вопрос: как передать некоторые аргументы в XML: обработчик Twig и как вернуть результат из обработчика.

Вот мой код, который жестко закодирован:

<counter name = "music", report type = "month", stringSet index = 4>.

Как реализовать это с помощью аргументов $counter_name, $type, $id?а как вернуть результат string_list?Спасибо (извините, я не разместил здесь XML-файл, потому что у меня возникли проблемы с этим. Все, что находится внутри <и>, игнорируется). 

use XML::Twig;

sub parse_a_counter {

     my ($twig, $counter) = @_;
     my @report = $counter->children('report[@type="month"]');

     for my $report (@report){

         my @stringSet = $report->children('stringSet[@index=”4”]');
         for my $stringSet (@stringSet){

             my @string_list = $stringSet->children_text('string');
             print @string_list;  #  in fact I want to return this string_list,
                                  #  not just print it.
         }
     }

     $counter->flush; # free the memory of $counter
}

my $roots = { 'counter[@name="music"]' => 1 };

my $handlers = { counter => \&parse_a_counter };

my $twig = new XML::Twig(TwigRoots => $roots,
                         TwigHandlers => $handlers);

$twig->parsefile('counter_test.xml');

Ответы [ 3 ]

4 голосов
/ 14 июля 2010

Самый простой и обычный способ передачи аргументов обработчикам - использовать замыкания. Это большое слово, но простая концепция: вы называете обработчик следующим образом: tag => sub { handler( @_, $my_arg) } и $my_arg будет передан обработчику. Достижение закрытия содержит более подробные объяснения концепции.

Ниже я хотел бы написать код. Я использовал Getopt::Long для обработки аргументов и qq{} вместо кавычек вокруг строк, содержащих выражение XPath, чтобы иметь возможность использовать кавычки в выражении. 

#!/usr/bin/perl
use strict;
use warnings;

use XML::Twig;

use Getopt::Long;

# set defaults
my $counter_name= 'music';
my $type= 'month';
my $id= 4;

GetOptions ( "name=s" => \$counter_name,
             "type=s" => \$type,
             "id=i"   => \$id,
           ) or die;   

my @results;

my $twig= XML::Twig->new( 
            twig_roots => { qq{counter[\@name="$counter_name"]} 
                             => sub { parse_a_counter( @_, $type, $id, \@results); } } )
                   ->parsefile('counter_test.xml');

print join( "\n", @results), "\n";

sub parse_a_counter {

     my ($twig, $counter, $type, $id, $results) = @_;
     my @report = $counter->children( qq{report[\@type="$type"]});

     for my $report (@report){

         my @stringSet = $report->children( qq{stringSet[\@index="$id"]});
         for my $stringSet (@stringSet){

             my @string_list = $stringSet->children_text('string');
             push @$results, @string_list;
         }
     }

     $counter->purge; # free the memory of $counter
}
1 голос
/ 12 июля 2010

Самый простой способ - заставить __parse_a_counter__ вернуть подпрограмму (т.е. замыкание) и сохранить результаты в глобальной переменной.Например: 

use strict;
use warnings;
use XML::Twig;

our @results;      # <= put results in here

sub parse_a_counter {
    my ($type, $index) = @_;

    # return closure over type & index
    return sub {
        my ($twig, $counter) = @_;
        my @report = $counter->children( qq{report[\@type="$type"]} );

        for my $report (@report) {
            my @stringSet = $report->children( qq{stringSet[\@index="$index"]} );

            for my $stringSet (@stringSet) {
                my @string_list = $stringSet->children_text( 'string' );
                push @results, \@string_list; 
            }
        }
    };
}

my $roots    = { 'counter[@name="music"]' => 1 };
my $handlers = { counter => parse_a_counter( "month", 4 ) };

my $twig = XML::Twig->new(
    TwigRoots    => $roots,                     
    TwigHandlers => $handlers,
)->parsefile('counter_test.xml');

Я проверил это с помощью следующего XML-кода (что я могу понять из вашего примера XML-кода): 

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <counter name="music">
        <report type="week">
            <stringSet index="4">
                <string>music week 4</string>
            </stringSet>
        </report> 
    </counter>
    <counter name="xmusic">
        <report type="month">
            <stringSet index="4">
                <string>xmusic month 4</string>
            </stringSet>
        </report> 
    </counter>
    <counter name="music">
        <report type="month"> 
            <stringSet index="4">
                <string>music month 4 zz</string>
                <string>music month 4 xx</string>
            </stringSet>
        </report>
    </counter>
</root>

И я получил следующее:

[
    [
        'music month 4 zz',
        'music month 4 xx'
    ]
];

Что я и ожидал!

1 голос
/ 12 июля 2010

ОТКАЗ ОТ ОТВЕТСТВЕННОСТИ: Я сам не использовал Twig, поэтому этот ответ может быть не идиоматичным - это общий ответ «как сохранить состояние в обработчике обратного вызова».

Три способа передачи информации в обработчики и из них:

ONE. Состояние удерживается в статическом месте 

package TwigState;

my %state = ();
# Pass in a state attribute to get
sub getState { $state{$_[0]} }
 # Pass in a state attribute to set and a value 
sub setState { $state{$_[0]} = $_[1]; }

package main;

sub parse_a_counter { # Better yet, declare all handlers in TwigState
     my ($twig, $element) = @_;
     my $counter = TwigState::getState('counter');
     $counter++;
     TwigState::setState('counter', $counter);
}

ВТОРАЯ. Состояние хранится в самом $ t (объекте XML :: Twig) в некотором элементе «state» 

# Ideally, XML::Twig or XML::Parser would have a "context" member 
# to store context and methods to get/set that context. 
# Barring that, simply make one, using a VERY VERY bad design decision
# of treating the object as a hash and just making a key in that hash.
# I'd STRONGLY not recommend doing that and choosing #1 or #3 instead,
# unless there's a ready made context data area in the class.
sub parse_a_counter {
     my ($twig, $element) = @_;
     my $counter = $twig->getContext('counter');
     # BAD: my $counter = $twig->{'_my_context'}->{'counter'};
     $counter++;
     TwigState::setState('counter', $counter);
     $twig->setContext('counter', $counter);
     # BAD: $twig->{'_my_context'}->{'counter'} = $counter;
}

# for using DIY context, better pass it in with constructor:
my $twig = new XML::Twig(TwigRoots    => $roots,
                         TwigHandlers => $handlers
                         _my_context  => {});

ТРЕТИЙ. Сделайте обработчик замыканием и сделайте так, чтобы он сохранял состояние таким образом

...