NSIS получить параметр - PullRequest
Новая
       4

NSIS получить параметр

1 голос
/ 09 ноября 2010

чтобы получить -n 0 значение, передаваемое установщику в виде строки (без необходимости), я не совсем понимаю, как работает эта функция? 

; GetParameters
 ; input, none
 ; output, top of stack (replaces, with e.g. whatever)
 ; modifies no other variables.

Function GetParameters

  Push $R0
  Push $R1
  Push $R2
  Push $R3

  StrCpy $R2 1
  StrLen $R3 $CMDLINE

  ;Check for quote or space
  StrCpy $R0 $CMDLINE $R2
  StrCmp $R0 '"' 0 +3
    StrCpy $R1 '"'
    Goto loop
  StrCpy $R1 " "

  loop:
    IntOp $R2 $R2 + 1
    StrCpy $R0 $CMDLINE 1 $R2
    StrCmp $R0 $R1 get
    StrCmp $R2 $R3 get
    Goto loop

  get:
    IntOp $R2 $R2 + 1
    StrCpy $R0 $CMDLINE 1 $R2
    StrCmp $R0 " " get
    StrCpy $R0 $CMDLINE "" $R2

  Pop $R3
  Pop $R2
  Pop $R1
  Exch $R0

FunctionEnd

1 Ответ

4 голосов
/ 09 ноября 2010

GetParameters просто получает параметры («yourapp.exe / foo / bar» выдаст вам «/ foo / bar» и т. Д.) По сути, он просто удаляет первый токен (с обработкой кавычек). Используйте GetOptions, чтобы получить значениепараметр. 

!include "FileFunc.nsh"
!include "LogicLib.nsh"

function .onInit
${GetParameters} $0
ClearErrors
${GetOptions} $0 "-n" $1
${IfNot} ${Errors}
    MessageBox mb_ok $1
${EndIf}
functionend
...