Erlang Динамический запуск супервизора gen_server - PullRequest
Новая
       26

Erlang Динамический запуск супервизора gen_server

3 голосов
/ 30 января 2011

У меня есть супервизор root, который создает другого супервизора: 

start_link() ->
    supervisor:start_link({local, ?MODULE}, ?MODULE, []).

init([]) ->
    RestartStrategy = {one_for_one, 5, 600},
    ListenerSup =
            {popd_listener_sup,
            {popd_listener_sup, start_link, []},
             permanent, 2000, supervisor, [popd_listener]},

    Children = [ListenerSup],

    {ok, {RestartStrategy, Children}}.

И у меня есть gen_server - слушатель.Как я могу запустить этот gen_server с popd_listener_sup супервизором, когда супервизор создан?

Спасибо.

1 Ответ

12 голосов
/ 30 января 2011

супервизор 

-module(root_sup).
-behaviour(supervisor).
-export([start_link/0]).
-export([init/1, shutdown/0]).

start_link() ->
     supervisor:start_link({local,?MODULE}, ?MODULE, []).

init(_Args) ->
     RestartStrategy = {one_for_one, 10, 60},
     ListenerSup = {popd_listener_sup,
          {popd_listener_sup, start_link, []},
          permanent, infinity, supervisor, [popd_listener_sup]},
     Children = [ListenerSup],
     {ok, {RestartStrategy, Children}}.    

% supervisor can be shutdown by calling exit(SupPid,shutdown)
% or, if it's linked to its parent, by parent calling exit/1.
shutdown() ->
     exit(whereis(?MODULE), shutdown).
     % or
     % exit(normal).

Если дочерний процесс является другим супервизором, Shutdown в дочерней спецификации должен быть установлен на infinity, чтобы дать поддереву достаточно времени для выключения, а Type должен быть установлен на supervisor, и это то, что мы сделали .

Детский воспитатель 

-module(popd_listener_sup).
-behaviour(supervisor).
-export([start_link/0]).
-export([init/1]).

start_link() ->
    supervisor:start_link({local,?MODULE}, ?MODULE, []).

init(_Args) ->
    RestartStrategy = {one_for_one, 10, 60},
    Listener = {ch1, {ch1, start_link, []},
            permanent, 2000, worker, [ch1]},
    Children = [Listener],
    {ok, {RestartStrategy, Children}}.

Здесь, в дочерней спецификации, мы устанавливаем значение Shutdown в 2000. Целочисленное значение тайм-аута означает, что супервизор скажет дочернему процессу завершиться, вызвав exit(Child,shutdown), а затем дождется сигнала выхода с отключением причины от дочернего процесса.

Слушатель 

-module(ch1).
-behaviour(gen_server).

% Callback functions which should be exported
-export([init/1]).
-export([handle_cast/2, terminate/2]).

% user-defined interface functions
-export([start_link/0]).

start_link() ->
     gen_server:start_link({local, ?MODULE}, ?MODULE, [], []).

init(_Args) ->
     erlang:process_flag(trap_exit, true),
     io:format("ch1 has started (~w)~n", [self()]),
     % If the initialization is successful, the function
     % should return {ok,State}, {ok,State,Timeout} ..
     {ok, []}.

handle_cast(calc, State) ->
     io:format("result 2+2=4~n"),
     {noreply, State};
handle_cast(calcbad, State) ->
     io:format("result 1/0~n"),
     1 / 0,
     {noreply, State}.

terminate(_Reason, _State) ->
     io:format("ch1: terminating.~n"),
     ok.

Из документации Erlang / OTP:

Если gen_server является частью дерево наблюдения и упорядочено его супервизор прекратить, функция Module:terminate(Reason, State) воля вызываться с Reason=shutdown, если применяются следующие условия:

  • gen_server был установлен для прерывания сигналов выхода, а
  • стратегия отключения, как определено в дочерней спецификации супервизора
    целочисленное значение тайм-аута, а не
    brutal_kill.

Вот почему мы назвали erlang:process_flag(trap_exit, true) в Module:init(Args).

Пример прогона

Запуск супервизора root: 

1> root_sup:start_link().
ch1 has started (<0.35.0>)
{ok,<0.33.0>}

Root supervisor запускается и автоматически запускает свои дочерние процессы, в нашем случае дочерний supervisor. Дочерний руководитель, в свою очередь, запускает свои дочерние процессы; в нашем случае у нас только один ребенок, ch1.

Давайте сделаем ch1 оценим нормальный код: 

2> gen_server:cast(ch1, calc).
result 2+2=4
ok

Теперь немного плохого кода: 

3> gen_server:cast(ch1, calcbad).
result 1/0
ok
ch1: terminating.

=ERROR REPORT==== 31-Jan-2011::01:38:44 ===
** Generic server ch1 terminating 
** Last message in was {'$gen_cast',calcbad}
** When Server state == []
** Reason for termination == 
** {badarith,[{ch1,handle_cast,2},
              {gen_server,handle_msg,5},
              {proc_lib,init_p_do_apply,3}]}
ch1 has started (<0.39.0>)
4> exit(normal).
ch1: terminating.
** exception exit: normal

Как вы можете видеть, дочерний процесс ch1 был перезапущен дочерним руководителем popd_listener_sup (уведомление ch1 has started (<0.39.0>)).

Поскольку наша оболочка и корневой супервизор связаны двунаправленно (вызов supervisor:start_link, а не supervisor:start в корневой функции супервизора start_link/0), exit(normal) привел к закрытию корневого супервизора, но его дочерние процессы имели некоторое время для убирать.

...