Удалить соответствующую n-ю строку до пустой строки в awk / sed / grep

Question

Мне нужно удалить n-ую строку соответствия в файле от совпадения до следующей пустой строки (т. Е. Один фрагмент текста с разделителями из пустой строки, начиная с n-го совпадения).

Answer 1

Это удалит фрагмент текста, который начинается и заканчивается пустой строкой, начинающейся с четвертой пустой строки.Также удаляются эти разделительные линии.

sed -n '/^$/!{p;b};H;x;/^\(\n[^\n]*\)\{4\}/{:a;n;/^$/!ba;d};x;p' inputfile

Измените первый /^$/, чтобы изменить начальное совпадение.Измените второй, чтобы изменить конечное совпадение.

Учитывая этот ввод:

aaa
---
bbb
---
ccc
---
ddd delete me
eee delete me
===
fff
---
ggg

Эта версия команды:

sed -n '/^---$/!{p;b};H;x;/^\(\n[^\n]*\)\{3\}/{:a;n;/^===$/!ba;d};x;p' inputfile

даст это в результате:

aaa
---
bbb
---
ccc
fff
---
ggg

Редактировать:

Я удалил постороннюю инструкцию b из команд sed выше.

Вот закомментированная версия:

sed -n '      # don't print by default
  /^---$/!{   # if the input line doesn't match the begin block marker
    p;        # print it
    b};       # branch to end of script and start processing next input line
  H;          # line matches begin mark, append to hold space
  x;          # swap pattern space and hold space
  /^\(\n[^\n]*\)\{3\}/{    # if what was in hold consists of 3 lines
                           # in other words, 3 copies of the begin marker
    :a;       # label a
    n;        # read the next line
    /^===$/!ba;    # if it's not the end of block marker, branch to :a
    d};       # otherwise, delete it, d branches to the end automatically
  x;          # swap pattern space and hold space
  p;          # print the line (it's outside the block we're looking for)
' inputfile   # end of script, name of input file

Любой однозначный шаблон должен работать для маркеров начала и конца.Они могут быть одинаковыми или разными.

Answer 2

perl -00 -pe 'if (/pattern/) {++$count == $n and $_ = "$`\n";}' file

-00 - чтение файла в режиме «параграфа» (разделитель записей - одна или несколько пустых строк)

$` - это специальная переменная Perl для «prematch» (текст впередняя часть соответствующего рисунка)

Answer 3

Обязательный скрипт awk.Просто измените значение n=2 на ваше n-е совпадение.

n=2; awk -v n=$n '/^HEADER$/{++i==n && ++flag} !flag; /^$/&&flag{flag=0}' ./file

Ввод

$ cat ./file
HEADER
line1a
line2a
line3a

HEADER
line1b
line2b
line3b

HEADER
line1c
line2c
line3c

HEADER
line1d
line2d
line3d

Ввод

$ n=2; awk -v n=$n '/^HEADER$/{++i==n&&++flag} !flag; /^$/&&flag{flag=0}' ./file
HEADER
line1a
line2a
line3a

HEADER
line1c
line2c
line3c

HEADER
line1d
line2d
line3d

Answer 4

В AWK

/m1/  {i++};

(i==3)  {while (getline temp > 0 && temp != "" ){}; if (temp == "") {i++;next}};

{print}  

Преобразует это:

m1 1
first

m1 2
second

m1 3
third delete me!

m1 4
fourth

m1 5
last

в это:

m1 1
first

m1 2
second

m1 4
fourth

m1 5
last  

удаляя третий блок "m1" ...

здесь работает на ideone

HTH!