Ввод пароля маски в консольном приложении - PullRequest
Новая
       4

Ввод пароля маски в консольном приложении

8 голосов
/ 08 сентября 2010

Я пишу консольное приложение, используя BDE 2006, и я хочу, чтобы он мог запрашивать строку пароля и маскировать ее "*", когда пользователь печатает. Я посмотрел вокруг, но я не мог найти примеры, как это сделать. Все, что я видел, было как сделать это в TEdit. Любые указатели о том, как это сделать?

Заранее спасибо,

Nic

Ответы [ 4 ]

8 голосов
/ 09 сентября 2010

Вот рабочее решение: 

program Project2;

{$APPTYPE CONSOLE}

uses
  SysUtils, Windows;

function GetPassword(const InputMask: Char = '*'): string;
var
  OldMode: Cardinal;
  c: char;
begin
  GetConsoleMode(GetStdHandle(STD_INPUT_HANDLE), OldMode);
  SetConsoleMode(GetStdHandle(STD_INPUT_HANDLE), OldMode and not (ENABLE_LINE_INPUT or ENABLE_ECHO_INPUT));
  try
    while not Eof do
    begin
      Read(c);
      if c = #13 then // Carriage Return
        Break;
      Result := Result + c;
      if c = #8 then // Back Space
        Write(#8)
      else
        Write(InputMask);
    end;
  finally
    SetConsoleMode(GetStdHandle(STD_INPUT_HANDLE), OldMode);
  end;
end;

begin
  try
    Writeln(Format(sLineBreak + 'pswd=%s',[GetPassword]));
    Readln;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

Обновление : обратите внимание, что приведенный выше код обрабатывает BackSpaces визуально, но сохраняет их встроенными в пароль, что может оказаться не тем, что вам нужно.
В этом случае их отфильтровывает следующий код: 

  if c = #13 then // Carriage Return
    Break;
  if (c = #8) and (Length(Result) > 0) then  // Back Space
  begin
    Delete(Result, Length(Result), 1);
    Write(#8);
  end
  else
  begin
    Result := Result + c;
    Write(InputMask);
  end;
2 голосов
/ 08 сентября 2010

У меня есть блок с procedure ConsoleGetPassword(const caption: String; var Password: string);, который делает то, что вы хотите

см. http://gist.github.com/570659

2 голосов
/ 08 сентября 2010

Это работает. 

program Project2;

{$APPTYPE CONSOLE}

uses
  SysUtils, Windows;

const
  BUF_LEN = 1024;

var
  amt, i, cmode: cardinal;
  buf: packed array[0..BUF_LEN - 1] of char;

begin
  try

    Write('Enter password: ');
    GetConsoleMode(GetStdHandle(STD_INPUT_HANDLE), cmode);
    SetConsoleMode(GetStdHandle(STD_INPUT_HANDLE), cmode and not ENABLE_ECHO_INPUT);
    ReadConsole(GetStdHandle(STD_INPUT_HANDLE), @buf[0], BUF_LEN, amt, nil);
    SetConsoleMode(GetStdHandle(STD_INPUT_HANDLE), cmode);

    Writeln;
    Writeln;

    Writeln('You entered: ');
    for i := 0 to amt - 3 do
      Write(buf[i]);
    Writeln;
    Writeln;

    Writeln('Done');
    Readln;

  except
    on E:Exception do
    begin
      Writeln(E.Classname, ': ', E.Message);
      Readln;
    end;
  end;
end.
0 голосов
/ 08 сентября 2010

Пожалуйста, ознакомьтесь с этой статьей на CodeProject , он может быть на C #, но он дает вам правильные подсказки и направление, включая ReadConsoleInput и WriteConsole API

...