Объедините два массива в ColdFusion

Question

Существует ли встроенный способ объединения двух массивов в ColdFusion, аналогичный JavaScript array.concat()?

Answer 1

Не совсем, но угадайте что, просто используйте Java!:)

<cfset foo = [1,2,3]>
<cfset bar = [4,5,6]>
<cfset foo.addAll( bar )>

ссылка: API интерфейса коллекции Java .

источник: http://www.aliaspooryorik.com/blog/index.cfm/e/posts.details/post/merging-two-arrays-267

Answer 2

CF10 +, используйте

arrayAppend(array1, array2, true);

https://helpx.adobe.com/coldfusion/cfml-reference/coldfusion-functions/functions-a-b/arrayappend.html

Answer 3

Если вы используете Railo , вы можете использовать ArrayMerge (Например, <cfset NewArray=ArrayMerge(FirstArray,SecondArray)>).

Answer 4

Довольно глупо, как в Coldfusion не хватает многих основных функций, которые можно ожидать от языка сценариев. Вот один, который я должен был написать быстро.

<cffunction name="mergeArrays" returntype="array" >
    <cfargument name="array1" type="array" required="true" >
    <cfargument name="array2" type="array" required="true" >

    <cfset arrayResult = arrayNew(1) >
    <cfloop array="#array1#" index="elem">
        <cfset arrayAppend(arrayResult,elem) >
    </cfloop>

    <cfloop array="#array2#" index="elem">
        <cfset arrayAppend(arrayResult,elem) >
    </cfloop>

    <cfreturn arrayResult>
</cffunction>

Answer 5

В CF 10 или Railo 4 вы можете использовать функцию concat () библиотеки Underscore.cfc , чтобы получить новый массив, который является объединением двух других массивов (без изменения существующих массивов) , Пример cfscript:

newArray = _.concat([1], [2]);

Результат:

// newArray == [1, 2]

Использование этого метода для получения нового массива немного чище, чем создание нового массива и двойной вызов ArrayAppend для него.

(Отказ от ответственности: я написал Underscore.cfc)

Answer 6

Вы можете легко объединить два списка следующим образом:

<cfset combolist = ListAppend(lista,listb, ",")>

Итак, сначала преобразуйте ваши два массива в списки, используя ArrayToList(). Объедините два списка с помощью ListAppend (), а затем преобразуйте ответ обратно в массив с ListToArray().

Я не знаю, насколько это эффективно, но код очень прост. Я хотел бы использовать arrayAppend (), но я в ColdFusion 8.

Answer 7

Я взял это у Бена Наделя и использовал его для шифрования и хэширования. Работал как шарм!

<cfscript>
    // Note: BinaryDecode/CharsetDecode return java arrays. 
    // Unlike CF arrays, java arrays are immutable, 
    // so the Java addAll(..) method to merge arrays won't work here. 
    // http://stackoverflow.com/a/10760835/104223

    // function to merge immutable arrays the long way
    function mergeArrays( array1, array2 ){
        var i = 0;
        var newArray = [];
        for (i = 1; i <= arrayLen(arguments.array1); i++) {
            arrayAppend(newArray, arguments.array1[i]);
        }
        for (i = 1; i <= arrayLen(arguments.array2); i++) {
            arrayAppend(newArray, arguments.array2[i]);
        }
        return newArray;
    }


    //convert the saltArray string and CustomerID string to UTF-8 byte arrays.
    saltByteArray = charsetDecode(salt, "utf-8");
    CustomerIdByteArray = charsetDecode(CustomerId, "utf-8");

    //create a new byte array consisting of the CustomerId bytes
    //appended with the salt bytes by merging the two binary arrays 
    //via custom function, mergeArrays
    mergedBytes = mergeArrays( CustomerIdByteArray, saltByteArray );
</cfscript>

Answer 8

В javascript array.join (s) создает строку из всех элементов массива, разделенных разделителем s.Функцией, аналогичной этой в ColdFusion, является функция ArrayToList.Что касается добавления массива к другому, я не верю, что для этого есть функция CF.Проверьте http://livedocs.adobe.com/coldfusion/8/htmldocs/help.html?content=functions-pt0_03.html#3473387, чтобы увидеть список функций Array в CF.Или попробуйте что-то вроде этого:

<cfscript>
   for(index = 1; index LTE ArrayLen(array2); i = i + 1) {
      ArrayAppend(array1, array2[i]);
  }
</cfscript>