Flash Webcam Permissions - PullRequest
Новая
       23

Flash Webcam Permissions

1 голос
/ 06 июля 2010

У меня проблема со вспышкой, с которой я не очень знаком. Я основываю этот код на том, что пришло с мультимедийным сервером wowza в примере с видеочатом, но в отличие от этого примера, flash не запрашивает у меня разрешение на использование видеокамеры.

Ниже приведен мой скрипт действий: 

import flash.events.MouseEvent;
import flash.events.NetStatusEvent;
import flash.media.Camera;
import flash.media.Microphone;
import flash.media.Video;
import flash.net.NetConnection;
import flash.net.NetStream;
import flash.system.Security;
import flash.system.SecurityPanel;
import flash.display.Sprite;
import flash.text.TextField;
import flash.events.StatusEvent;

public class QandA extends Sprite {
    Security.LOCAL_TRUSTED;

    private var nc:NetConnection = null;
    private var camera:Camera;
    private var microphone:Microphone;
    private var nsPublish:NetStream = null;                      
    private var nsPlay:NetStream = null;
    private var videoCamera:Video;
    public var prompt:TextField;

    public function QandA():void {
        stage.align = "TL";
        stage.scaleMode = "noScale";
        videoCamera = new Video(160,120);
        addChild(videoCamera);
        camera = Camera.getCamera();
        microphone = Microphone.getMicrophone();
        if (camera.muted) {
            trace("Camera Muted");
            Security.showSettings(SecurityPanel.CAMERA);
            camera.addEventListener(StatusEvent.STATUS, statusHandler);
        } else {
            startCamera();
        }

    }

    private function statusHandler(e:StatusEvent):void {
        if (e.code == "Camera.Unmuted") {
            trace("Camera Unmuted");
            startCamera();
            camera.removeEventListener(StatusEvent.STATUS, statusHandler);
        } else {
            trace("StatusEvent: " + e.code + " " + e.toString());
        }
    }

    private function startCamera():void {
        // here are all the quality and performance settings that we suggest
        camera.setMode(160, 120, 12, false);
        camera.setQuality(0, 75);
        camera.setKeyFrameInterval(24);
        microphone.rate = 11;
        microphone.setSilenceLevel(0);

        nc = new NetConnection();
        nc.connect("rtmp://localhost/live/");

        // get status information from the NetConnection object
        nc.addEventListener(NetStatusEvent.NET_STATUS, ncOnStatus); 
    }

    private function nsPublishOnStatus(infoObject:NetStatusEvent):void
    {
        trace("nsPublish: "+infoObject.info.code+" ("+infoObject.info.description+")");
    }

    private function ncOnStatus(infoObject:NetStatusEvent):void
    {
        trace("nc: "+infoObject.info.code+" ("+infoObject.info.description+")");
        nsPublish = new NetStream(nc);
        nsPublish.addEventListener(NetStatusEvent.NET_STATUS, nsPublishOnStatus);
        nsPublish.bufferTime = 0;
        nsPublish.publish("testing");
        // attach the camera and microphone to the server
        nsPublish.attachCamera(camera);
        nsPublish.attachAudio(microphone);
    }
}

Я довольно уверен, что это что-то простое; как я видел этот код в / на бесчисленных сайтах, когда обсуждали, как публиковать на живом сервере.

Любая помощь будет принята с благодарностью. Я попытался использовать этот код на веб-сервере, чтобы проверить, были ли это просто локальные настройки безопасности, но это не так.

Журналы, которые я получаю при отладке приложения во Flash CS5:

Попытка запустить и подключиться к Player, используя URL D: \ development \ qanda \ qandaHost.swf
[SWF] D: \ development \ qanda \ qandaHost.swf - 3583 байта после распаковки
Камера отключена
nc: NetConnection.Connect.Success (Соединение установлено.)
nsPublish: NetStream.Publish.Start (тестирование публикации.)

Ответы [ 2 ]

2 голосов
/ 08 апреля 2011

Ниже неправильно: 

Security.showSettings(SecurityPanel.**CAMERA**);

Вы должны написать: 

Security.showSettings(SecurityPanel.**PRIVACY**);
1 голос
/ 06 июля 2010

Я не прикреплял камеру к видео, поэтому я не мог видеть себя, хотя видео на самом деле было потоковым. 

private function startCamera():void {
    trace("Attempting to start camera");
    // here are all the quality and performance settings that we suggest
    camera.setMode(160, 120, 12, false);
    camera.setQuality(0, 75);
    camera.setKeyFrameInterval(24);
    videoCamera.attachCamera(camera);
    microphone.rate = 11;
    microphone.setSilenceLevel(0);
}
...