Oracle BLOB извлечение очень медленно - PullRequest
Новая
       11

Oracle BLOB извлечение очень медленно

3 голосов
/ 09 декабря 2010

У меня проблемы с производительностью при извлечении BLOBS из базы данных Oracle 10gR2 10.2.05, которую я администрирую. У меня есть около 400 файлов, хранящихся в виде BLOB-файлов, которые мне нужно записать в файловую систему. Ниже мой код. Когда я выполняю эту процедуру, первые 8 или около того файлов записываются в течение нескольких секунд, и оттуда все замедляется в геометрической прогрессии, где-то около 1 файла каждые 40 секунд после первого 8. Для меня это не имеет никакого смысла, почему первые 8 файлов будут быстрыми, но после этого все замедляется. Я попытался запустить это как хранимую процедуру, изменив UTL_FILE.fopen на «wb» (запись двоичного кода), а также используя смонтированную файловую систему NFS, чтобы не снижать производительность базы данных. Ничто из этого не имело никакого влияния. При такой скорости мне понадобится 6 часов, чтобы извлечь 400 файлов, которые в среднем занимают около 1,5 МБ каждый. Кто-нибудь видит что-то не так с моим кодом или знает лучший способ сделать это? Кстати, я использовал этот пример кода, найденный здесь http://www.oracle -base.com / article / 9i / ExportBlob9i.php в качестве отправной точки.

Спасибо за любую помощь! 

DECLARE
  TYPE comment_text IS TABLE OF documents.comment_text%TYPE;
  TYPE localdata IS TABLE OF documents.localdata%TYPE;
  l_file UTL_FILE.FILE_TYPE;
  l_buffer RAW(32767);
  l_amount BINARY_INTEGER := 32767;
  l_pos INTEGER := 1;
  l_blob localdata;
  l_fname comment_text;
  l_blob_len INTEGER;
  l_x NUMBER := 1;
BEGIN
  SELECT comment_text, localdata
  BULK COLLECT INTO l_fname, l_blob
  FROM documents
  WHERE user_id='BILLYBOB';
  IF SQL%ROWCOUNT =0 THEN
    DBMS_OUTPUT.PUT_LINE('No records found!');
  ELSE
    FOR i IN l_fname.FIRST .. l_fname.LAST
    LOOP
      l_blob_len := DBMS_LOB.getlength(l_blob(i));
      DBMS_OUTPUT.PUT_LINE(l_blob_len);
      l_file := UTL_FILE.fopen('BLOBS',l_x || '_' || l_fname(i),'w', 32767);
      l_pos := 1;
      l_x := l_x + 1;
      WHILE l_pos < l_blob_len
      LOOP
        DBMS_LOB.read(l_blob(i), l_amount, l_pos, l_buffer);
        UTL_FILE.put_raw(l_file, l_buffer, TRUE);
        l_pos := l_pos + l_amount;
      END LOOP;
      UTL_FILE.fclose(l_file);
    END LOOP;
  END IF;
END;

1 Ответ

1 голос
/ 09 декабря 2010

Я почти уверен, что вам не следует извлекать все BLOB-объекты в массив в начале процедуры.Поскольку вы читаете данные BLOB и фактически никогда не закрываете локатор лобов, Oracle должен хранить всю эту информацию в памяти.Я думаю, это случай переполнения памяти.

Попробуйте вместо этого: 

CURSOR cc IS (SELECT ...)
BEGIN
   OPEN cc;
   LOOP
      FETCH cc
         INTO l_fname, l_blob;
      EXIT WHEN cc%NOTFOUND;
      l_blob_len := DBMS_LOB.getlength(l_blob);
      DBMS_OUTPUT.PUT_LINE(l_blob_len);
      l_file := UTL_FILE.fopen('BLOBS', l_x || '_' || l_fname, 'w', 32767);
      l_pos  := 1;
      l_x    := l_x + 1;
      WHILE l_pos < l_blob_len LOOP
         DBMS_LOB.READ(l_blob, l_amount, l_pos, l_buffer);
         UTL_FILE.put_raw(l_file, l_buffer, TRUE);
         l_pos := l_pos + l_amount;
      END LOOP;
      UTL_FILE.fclose(l_file);
   END LOOP;
   CLOSE cc;
END;
...