советы по созданию диаграмм Графа - PullRequest
Новая
       125

советы по созданию диаграмм Графа

14 голосов
/ 04 ноября 2010

Я хотел бы программно создавать подобные диаграммы http://yaroslavvb.com/upload/junction-tree-decomposition.png

Я полагаю, мне следует использовать GraphPlot с VertexCoordinateRules, VertexRenderingFunction и EdgeRenderingFunction для графиков Что я должен использовать для цветных скошенных фонов?

Редактировать Используя в основном идеи Саймона, вот упрощенная «менее надежная» версия, которую я в итоге использовал 

Needs["GraphUtilities`"];
GraphPlotHighlight[edges_, verts_, color_] := Module[{},
  vpos = Position[VertexList[edges], Alternatives @@ verts];
  coords = Extract[GraphCoordinates[edges], vpos];
  (* add .002 because end-cap disappears when segments are almost colinear *)  
  AppendTo[coords, First[coords] + .002];
  Show[Graphics[{color, CapForm["Round"], JoinForm["Round"], 
     Thickness[.2], Line[coords], Polygon[coords]}],
   GraphPlot[edges], ImageSize -> 150]
  ]

SetOptions[GraphPlot, 
  VertexRenderingFunction -> ({White, EdgeForm[Black], Disk[#, .15], 
      Black, Text[#2, #1]} &), 
  EdgeRenderingFunction -> ({Black, Line[#]} &)];
edges = GraphData[{"Grid", {3, 3}}, "EdgeRules"];
colors = {LightBlue, LightGreen, LightRed, LightMagenta};
vsets = {{8, 5, 2}, {7, 5, 8}, {9, 6, 3}, {8, 1, 2}};
MapThread[GraphPlotHighlight[edges, #1, #2] &, {vsets, colors}]

http://yaroslavvb.com/upload/mathematica-graphs.png

Ответы [ 3 ]

11 голосов
/ 04 ноября 2010

Немного обобщив ответ Самсдрама, я получаю 

GraphPlotHighlight[edges:{((_->_)|{_->_,_})..},hl:{___}:{},opts:OptionsPattern[]]:=Module[{verts,coords,g,sub},
  verts=Flatten[edges/.Rule->List]//.{a___,b_,c___,b_,d___}:>{a,b,c,d};
  g=GraphPlot[edges,FilterRules[{opts}, Options[GraphPlot]]];
  coords=VertexCoordinateRules/.Cases[g,HoldPattern[VertexCoordinateRules->_],2];
  sub=Flatten[Position[verts,_?(MemberQ[hl,#]&)]];
  coords=coords[[sub]];     
  Show[Graphics[{OptionValue[HighlightColor],CapForm["Round"],JoinForm["Round"],Thickness[OptionValue[HighlightThickness]],Line[AppendTo[coords,First[coords]]],Polygon[coords]}],g]
]
Protect[HighlightColor,HighlightThickness];
Options[GraphPlotHighlight]=Join[Options[GraphPlot],{HighlightColor->LightBlue,HighlightThickness->.15}];

Некоторые из приведенного выше кода могут быть немного более надежными, но это работает: 

GraphPlotHighlight[{b->c,a->b,c->a,e->c},{b,c,e},VertexLabeling->True,HighlightColor->LightRed,HighlightThickness->.1,VertexRenderingFunction -> ({White, EdgeForm[Black], Disk[#, .06], 
Black, Text[#2, #1]} &)]

Mathematica graphics

РЕДАКТИРОВАТЬ # 1: Уточненную версию этого кода можно найти по адресу http://gist.github.com/663438

РЕДАКТИРОВАТЬ # 2: Как обсуждалось в комментариях ниже, шаблон, которому должен соответствовать edges, представляет собой список правил края с необязательными метками. Это немного менее общее, чем то, что используется функцией GraphPlot (и версией в приведенном выше gist ), где правила ребер также могут быть заключены в Tooltip.

Чтобы найти точный шаблон, используемый GraphPlot, я неоднократно использовал Unprotect[fn];ClearAttributes[fn,ReadProtected];Information[fn], где fn - интересующий объект, пока не обнаружил, что он использовал следующую (очищенную) функцию: 

Network`GraphPlot`RuleListGraphQ[x_] := 
  ListQ[x] && Length[x] > 0 && 
    And@@Map[Head[#1] === Rule 
         || (ListQ[#1] && Length[#1] == 2 && Head[#1[[1]]] === Rule) 
         || (Head[#1] === Tooltip && Length[#1] == 2 && Head[#1[[1]]] === Rule)&, 
      x, {1}]

Я думаю, что мой edges:{((_ -> _) | (List|Tooltip)[_ -> _, _])..} шаблон эквивалентен и более лаконичен ...

5 голосов
/ 04 ноября 2010

Для простых примеров, когда вы соединяете только два узла (как ваш пример справа), вы можете нарисовать линии с ограниченными конечными точками, как это. 

vertices = {a, b};
Coordinates = {{0, 0}, {1, 1}};
GraphPlot[{a -> b}, VertexLabeling -> True, 
 VertexCoordinateRules -> 
  MapThread[#1 -> #2 &, {vertices, Coordinates}], 
 Prolog -> {Blue, CapForm["Round"], Thickness[.1], Line[Coordinates]}]

Mathematica graphics

Для более сложных примеров (например, второй справа) я бы порекомендовал нарисовать многоугольник, используя координаты вершины, а затем обведя границу многоугольника с помощью ограниченной линии.Я не мог найти способ добавить скошенный край непосредственно к многоугольнику.При трассировке периметра многоугольника необходимо добавить координату первой вершины к концу отрезка, чтобы линия составляла полный периметр многоугольника.Кроме того, есть две отдельные графические директивы для линий CapForm, которые определяют, следует ли наклонять концы линии, и JoinForm, которая определяет, следует ли наклонять промежуточные точки линии. 

vertices = {a, b, c};
Coordinates = {{0, 0}, {1, 1}, {1, -1}};
GraphPlot[{a -> b, b -> c, c -> a}, VertexLabeling -> True, 
 VertexCoordinateRules -> 
  MapThread[#1 -> #2 &, {vertices, Coordinates}], 
 Prolog -> {Blue, CapForm["Round"], JoinForm["Round"], Thickness[.15],
    Line[AppendTo[Coordinates, First[Coordinates]]], 
   Polygon[Coordinates]}]

Mathematica graphics

4 голосов
/ 04 ноября 2010

JoinForm ["Round"] будет округлять объединения отрезков.

Вам понадобится заполненный многоугольник вокруг центров вершин в цветной области, затем JoinForm["Round"], ..., Line[{...}], чтобы получить закругленные углы.

Рассмотрим 

foo = GraphPlot[{a -> b, a -> c, b -> d, b -> e, b -> f, c -> e, e -> f}, 
    VertexRenderingFunction -> 
    ({White, EdgeForm[Black], Disk[#, .1], Black, Text[#2, #1]} &)]
Show[
    Graphics[{
      RGBColor[0.6, 0.8, 1, 1],
      Polygon[foo[[1, 1, 1, 1, 1, {2, 5, 6, 2}]]],
      JoinForm["Round"], Thickness[0.2],
      Line[foo[[1, 1, 1, 1, 1, {2, 5, 6, 2}]]]
    }],
    foo
]
Mathematica graphics

где foo [[1,1,1,1,1]] - список центров вершин, а {2,5,6} вытаскивает вершины {b, e, f}. ({2,5,6,2} закрывает строку в исходной точке.)

Существует достаточно места для предварительного употребления, но я думаю, что это покрывает ингредиент, который вы не упомянули выше.

...