Есть ли какой-нибудь модуль Perl для установки объекта из конфигурации по умолчанию плюс хэш-функция необязательных конфигураций? - PullRequest
Новая
       2

Есть ли какой-нибудь модуль Perl для установки объекта из конфигурации по умолчанию плюс хэш-функция необязательных конфигураций?

6 голосов
/ 08 июля 2010

Я постоянно пишу и переписываю следующий вид кода: 

 my %default = (x => "a", y => "b");
 sub new
 {
      my ($package, $config) = @_;
      my $self = {%default};
      for my $k (keys %default) {
           $self->{$k} = $config->{$k} if defined $config->{$k};
      }
      for my $k (keys %$config) {
           if (! exists $default{$k}) {
                carp "Unknown config option $k\n";
           }
      }
      bless $self;
      # etc. etc.
 }

Прежде чем я сделал свой собственный модуль для этого, мне просто было интересно, есть ли что-нибудь еще на CPAN, как это? Я просто хочу эту очень простую вышеописанную функциональность, поэтому предложение использовать Moose не является подходящим ответом на этот вопрос.

Ответы [ 3 ]

11 голосов
/ 08 июля 2010

Moose поддерживает значения по умолчанию для атрибутов, например: 

has 'foo' => ( is => 'rw', isa => 'Int', default => 42 );

Но если вы не хотите идти по маршруту Moose, более простой способ достижения желаемого:

sub new { 
    my ( $package, %config ) = @_;

    my %defaults = ( x => 'a', y => 'b' );

    my $self = { %defaults, %config };

    # error checking here

    return bless $self, $package;
}

Поскольку указание одного и того же ключа хеширования дважды при инициализации хэша приведет к засорению первого ключа, любые ключи в %config просто переопределяют ключи в %defaults.

4 голосов
/ 08 июля 2010

Params :: Validate может помочь.Это позволит вам удалить хэш %defaults и указать значения по умолчанию для каждого (возможно, необязательного) параметра.

Кроме того, вы можете сделать это немного менее многословным, используя map.Конечно, это будет игнорировать недопустимые аргументы. 

#!/usr/bin/perl

package My::Class;

use strict; use warnings;

my %defaults = ( x => 'a', y => 'b' );

sub new {
    my $class = shift;
    my ($args) = @_;

    my $self = {
        %defaults,
        map {
            exists $args->{$_} ? ($_ => $args->{$_}) : ()
        } keys %defaults,
    };

    return bless $self, $class;
}

package main;

use strict; use warnings;

my $x = My::Class->new({ x => 1, z => 10});

use YAML;
print Dump $x;

Вывод: 

--- !!perl/hash:My::Class
x: 1
y: b
3 голосов
/ 08 июля 2010

Если вы уже используете Moose в своих модулях, вы можете получить это поведение, комбинируя MooseX :: Getopt и MooseX :: SimpleConfig .Ваш конфигурационный файл может содержать значения по умолчанию, а затем вы можете переопределить что угодно, передав эти значения конструктору: 

my $obj = Class->new_with_options(configfile => "myconfig.yaml", key1 => 'val', key2 => 'val');

package Class;
use Moose;
with 'MooseX::Getopt::Strict',
    'MooseX::SimpleConfig';

has configfile => (
    is => 'ro', isa => 'Str',
    traits => ['Getopt'],
    documentation => 'File containing default configs',
    lazy => 1,
    default => sub { File::Spec->catfile($base_dir, 'my_default_config.yaml') },
);

has [ qw(key1 key2) ] => (
    is => 'ro', isa => 'Str',
);
...