Оберните слова в теги, используя XSLT - PullRequest
Новая
       5

Оберните слова в теги, используя XSLT

3 голосов
/ 04 февраля 2011

Как мне обернуть теги span (или любой тег) вокруг отдельных слов в XSLT? Я использую XSLT1, но, кажется, застреваю при каждой попытке.

По сути, я хочу передать абзац (или строку текста): 

<p>This is my text!</p>

и оберните каждое слово следующим образом, сохранив пробел и пунктуацию между каждым словом: 

<p><span class="word-1">This</span> <span class="word-2">is</span> <span class="word-3">my</span> <span class="word-4">text!</span>

Это в основном для презентационных целей, я был бы признателен за любую помощь

Ответы [ 2 ]

4 голосов
/ 04 февраля 2011

Эта таблица стилей: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:param name="pSeparators">&#xA;&#x9;&#x20;,.;:?!()'"</xsl:param>
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="p/text()" name="tokenize">
        <xsl:param name="pString" select="."/>
        <xsl:param name="pMask"
                   select="translate(.,translate(.,$pSeparators,''),'')"/>
        <xsl:param name="pCount" select="1"/>
        <xsl:choose>
            <xsl:when test="not($pString)"/>
            <xsl:when test="$pMask">
                <xsl:variable name="vSeparator"
                              select="substring($pMask,1,1)"/>
                <xsl:variable name="vString"
                              select="substring-before($pString,$vSeparator)"/>
                <xsl:call-template name="tokenize">
                    <xsl:with-param name="pString" select="$vString"/>
                    <xsl:with-param name="pMask"/>
                    <xsl:with-param name="pCount" select="$pCount"/>
                </xsl:call-template>
                <xsl:value-of select="$vSeparator"/>
                <xsl:call-template name="tokenize">
                    <xsl:with-param name="pString"
                               select="substring-after($pString,$vSeparator)"/>
                    <xsl:with-param name="pMask"
                                    select="substring($pMask,2)"/>
                    <xsl:with-param name="pCount"
                                    select="$pCount + boolean($vString)"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <span class="word-{$pCount}">
                    <xsl:value-of select="$pString"/>
                </span>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

Вывод: 

<p><span class="word-1">This</span> <span class="word-2">is</span> <span class="word-3">my</span> <span class="word-4">text</span>!</p>

Примечание : токенизироваться несколькими разделителями. Редактировать : лучшие имена.Добавление пробельных символов в последовательность разделителей.

3 голосов
/ 04 февраля 2011

Простой рекурсивный именованный шаблон должен сделать трюк: 

  <xsl:template name="wordsInTags">
      <xsl:param name="text"
                 select="."/>
      <xsl:param name="index"
                 select="1"/>
      <xsl:choose>
        <xsl:when test="contains($text, ' ')">
          <span class="word-{$index}">
            <xsl:value-of select="substring-before($text, ' ')"/>
          </span>
          <xsl:text> </xsl:text>
          <xsl:call-template name="wordsInTags">
            <xsl:with-param name="text">
              <xsl:value-of select="substring-after($text, ' ')"/>
            </xsl:with-param>
            <xsl:with-param name="index">
              <xsl:value-of select="$index + 1"/>
            </xsl:with-param>
          </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
          <span class="word-{$index}">
            <xsl:value-of select="$text"/>
          </span>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:template>

И затем просто вызвать его для элемента, в который нужно обернуть слова: 

    <xsl:template match="p">
      <p>
        <xsl:call-template name="wordsInTags"/>
      </p>
    </xsl:template>

Бросилвместе очень быстро, так что может потребоваться дополнительная работа, но это должно помочь вам начать.

...