Как преобразовать postfix_expression в грамматике ANTLR C в AST? - PullRequest
Новая
       16

Как преобразовать postfix_expression в грамматике ANTLR C в AST?

2 голосов
/ 09 октября 2011

Я изучаю ANTLR, изменяя грамматику C и пробуя что-то интересующее меня.Я начал с грамматики C: http://www.antlr.org/grammar/1153358328744/C.g

Теперь я хочу преобразовать postfix_expression в соответствующее ему AST, но ничего не знал о преобразовании формы xx (aa|bb|cc)* yy

...
unary_expression
  : postfix_expression
  | unary_operator^ unary_expression
  ;

postfix_expression
  : primary_expression
  ( '[' expression ']'
  | '(' ')'
  | '(' argument_expression_list ')'
  | '.' ID
  )*
  ;

unary_operator
  : '+'
  | '-'
  | '~'
  | '!'
  ;
...

Можете ли вы помочь мне с этой проблемой?Вы можете просто добавить некоторые обозначения ^ и / или ! к части postfix_expression в грамматике.

1 Ответ

1 голос
/ 09 октября 2011

Я бы пошел на что-то вроде этого: 

grammar T;

options {
  output=AST;
}

tokens {
  ROOT;
  MEMBER;
  INDEX;
  CALL;
}

parse
  :  unary_expression EOF -> ^(ROOT unary_expression)
  ;

unary_expression
  :  postfix_expression
  |  unary_operator unary_expression -> ^(unary_operator unary_expression)
  ;

postfix_expression
  :  primary_expression tail* -> ^(primary_expression tail*)
  ;

tail
  :  '[' expression ']'                -> ^(INDEX expression)
  |  '(' argument_expression_list? ')' -> ^(CALL argument_expression_list?)
  |  '.' ID                            -> ^(MEMBER ID)
  ;

primary_expression
  :  ID
  |  '(' expression ')' -> expression
  ;

argument_expression_list
  :  expression (',' expression)* -> expression+
  ;

unary_operator
  :  '+'
  |  '-'
  |  '~'
  |  '!'
  ;

expression
  :  NUMBER
  |  ID
  ;

NUMBER : '0'..'9'+;
ID     : ('a'..'z' | 'A'..'Z')+;

, который будет анализировать ввод: 

a.b.c(foo,42)[123]

в следующие AST:

enter image description here

облегчает вычисление выражения слева направо.

...