как изменить exe.config из скрипта Innosetup - PullRequest
Новая
       15

как изменить exe.config из скрипта Innosetup

5 голосов
/ 07 марта 2012

Я начал изучать сценарии Innosetup самостоятельно. Для этого я создал простое консольное приложение C #, которое считывает элемент из файла конфигурации и выводит его на консоль. 

<configuration>
  <appSettings>
    <add key ="Name" value="Brad Pitt"/> 
  </appSettings>
</configuration>

Например: он должен прочитать значение путем запроса ключевого атрибута «Имя».

Я хочу, чтобы значение в .config было записано из сценария установки Innosetup.

т.е. во время процесса установки я собираю имя (т.е. в данном случае "Брэд Питт") и записываю его в значение файла конфигурации 

<add key ="Name" value="Brad Pitt"/>

Вопрос в том, как мне этого добиться, используя скрипт на Паскале или стандартный скрипт.

Любое руководство высоко ценится

Привет

ватс

Ответы [ 3 ]

7 голосов
/ 07 марта 2012

Для этого я создал простую процедуру, которая принимает имя файла xml в качестве входного.Процедура должна проанализировать каждую строку и записать содержимое во временный файл.Код проверяет каждую строку в поисках строки 'key = "Name"': 

   if (Pos('key="Name"', strTest) <> 0 )

. Если совпадение найдено, я заменяю эту конкретную строку желаемым тегом, из которого получается valueс моей пользовательской страницы. 

   strTest := '  <add key="Name" value="' + strName + '"/> ';

Это записывается во временный файл.Затем я удаляю исходный файл exe.config и переименовываю временный файл конфигурации в файл exe.config (таким образом, отражая необходимые мне изменения).Ниже приведен весь фрагмент кода для процедуры, и не забудьте вызвать процедуру из [Files], т.е. 

[Files]
Source: "HUS.exe.config"; DestDir: "{app}"; AfterInstall: ConvertConfig('HUS.exe.config')

Фрагмент кода 

procedure ConvertConfig(xmlFileName: String);
var
  xmlFile: String;
  xmlInhalt: TArrayOfString;
  strName: String;
  strTest: String;
  tmpConfigFile: String;
  k: Integer;
begin
  xmlFile := ExpandConstant('{app}') + '\' + xmlFileName;
  tmpConfigFile:= ExpandConstant('{app}') + '\config.tmp';
  strName :=  UserPage.Values[0] +' '+ UserPage.Values[1];

  if (FileExists(xmlFile)) then begin
    // Load the file to a String array
    LoadStringsFromFile(xmlFile, xmlInhalt);

    for k:=0 to GetArrayLength(xmlInhalt)-1 do begin
      strTest := xmlInhalt[k];
      if (Pos('key="Name"', strTest) <> 0 ) then  begin
        strTest := '  <add key="Name" value="' + strName + '"/> ';
      end;
      SaveStringToFile(tmpConfigFile, strTest + #13#10,  True);
    end;

    DeleteFile(xmlFile); //delete the old exe.config
    RenameFile(tmpConfigFile,xmlFile);
  end;
end;
4 голосов
/ 11 февраля 2013

Я знаю, что сейчас немного устарело, но вот другой подход;используйте MSXML 

procedure UpdateConfig();
var
  XMLDoc, NewNode, RootNode, Nodes, Node: Variant;
  ConfigFilename, Key: String;
  i: integer;

begin
  ConfigFilename := ExpandConstant('{app}') + '\your-app-name.exe.config';

  try
      XMLDoc := CreateOleObject('MSXML2.DOMDocument');
  except
    RaiseException('MSXML is required to complete the post-installation process.'#13#13'(Error ''' + GetExceptionMessage + ''' occurred)');
  end;  

  XMLDoc.async := False;
  XMLDoc.resolveExternals := False;
  XMLDoc.load(ConfigFilename);
  if XMLDoc.parseError.errorCode <> 0 then
    RaiseException('Error on line ' + IntToStr(XMLDoc.parseError.line) + ', position ' + IntToStr(XMLDoc.parseError.linepos) + ': ' + XMLDoc.parseError.reason);

  RootNode := XMLDoc.documentElement;
  Nodes := RootNode.selectNodes('//configuration/appSettings/add');
  for i := 0 to Nodes.length - 1 do
  begin
    Node := Nodes.Item[i];
    if Node.NodeType = 1 then
    begin
      key := Node.getAttribute('key');
      Case key of
        'MyValue1' : Node.setAttribute('value', ConfigPage.Values[0]);
        'MyValue2' : Node.setAttribute('value', ConfigPage.Values[1]);
        'MyValue3' : Node.setAttribute('value', ConfigPage.Values[2]);
      end;
    end;
  end;

  XMLDoc.Save(ConfigFilename); 

end;

Cheers, Matt

1 голос
/ 07 февраля 2018

Просто вносим свой вклад, здесь следует обновление вышеописанной процедуры, теперь получая параметры, которые будут использоваться с любым атрибутом: 

procedure UpdateConfigKeyValue(ConfigFilename,NodeName,KeyName,Value:String);
var
  XMLDoc, NewNode, RootNode, Nodes, Node: Variant;
  Key: String;
  i: integer;
begin
  try
      XMLDoc := CreateOleObject('MSXML2.DOMDocument');
  except
    RaiseException('MSXML is required to complete the post-installation process.'#13#13'(Error ''' + GetExceptionMessage + ''' occurred)');
  end;  

  XMLDoc.async := False;
  XMLDoc.resolveExternals := False;
  XMLDoc.load(ConfigFilename);
  if XMLDoc.parseError.errorCode <> 0 then
    RaiseException('Error on line ' + IntToStr(XMLDoc.parseError.line) + ', position ' + IntToStr(XMLDoc.parseError.linepos) + ': ' + XMLDoc.parseError.reason);

  RootNode := XMLDoc.documentElement;
  Nodes := RootNode.selectNodes(NodeName);
  for i := 0 to Nodes.length - 1 do
  begin
    Node := Nodes.Item[i];
    if Node.NodeType = 1 then
    begin
      key := Node.getAttribute('key');
      Case key of
        KeyName : Node.setAttribute('value', Value);
      end;
    end;
  end;

  XMLDoc.Save(ConfigFilename); 

end;

Пример использования: 

UpdateConfigKeyValue(ConfigPath,'//configuration/appSettings/add','hibernate.connection.data_source',SQLServer);
...