Какие инструкции XSLT изменяют текущий узел, кроме for-each? - PullRequest
Новая
       8

Какие инструкции XSLT изменяют текущий узел, кроме for-each?

6 голосов
/ 10 августа 2011

У меня есть этот ввод: 

<school>
    <faculty>
        <area>
            <name>F1A1</name>
        </area>
        <area>
            <name>F1A2</name>
        </area>
        <area>
            <name>F1A3</name>
        </area>
    </faculty>
    <faculty>
        <area>
            <name>F2A1</name>
        </area>
        <area>
            <name>F2A2</name>
        </area>
        <area>
            <name>F2A3</name>
        </area>
    </faculty>
    <faculty>
        <area>
            <name>F3A1</name>
        </area>
        <area>
            <name>F3A2</name>
        </area>
        <area>
            <name>F3A3</name>
        </area>
    </faculty>
</school>

, и я хочу получить этот вывод (числа в скобках - длина строки): 

F1A1 (4)
F1A2 (4)
F1A3 (4)
F2A1 (4)
F2A2 (4)
F2A3 (4)
F3A1 (4)
F3A2 (4)
F3A3 (4)

Вот требования:

A.начальное совпадение должно быть <xsl:template match="/">.

B.шаблон T1 определяется следующим образом: 

<xsl:template name="T1">

   <xsl:value-of select="concat(.,' (',string-length(.),')&#10;')"/>

</xsl:template>

Сценарий требуется для call-template T1 для генерации требуемого вывода, и T1 нельзя изменять каким-либо образом.

C.Не должно быть никакой зависимости от встроенных шаблонных правил по умолчанию в XSLT.

Это мое решение (выглядит странно): 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" indent="yes"/>
    <xsl:template match="/">
        <xsl:for-each select="school/faculty">
            <xsl:for-each select="area">
                <xsl:for-each select="name">
                    <xsl:call-template name="T1"/>
                </xsl:for-each>
            </xsl:for-each>
        </xsl:for-each>
    </xsl:template>
    <xsl:template name="T1">
        <xsl:value-of select="concat(.,' (',string-length(.),')&#10;')"/>
    </xsl:template>
</xsl:stylesheet>

С одной стороны, я использую<xsl:for-each select="name"> просто изменить current node на name, так как я не могу сделать select, пока call-template.ну, я знаю, просто никто не пишет код таким образом, поскольку мы вообще откажемся от call-template и выберем apply-template, но я просто пытаюсь решить эту проблему.

Итак, в основном мой вопрос таков:кроме <xsl:for-each select="name">, какие другие инструкции XSLT могут изменить текущий узел ?

Бонусный вопрос: есть ли другой способ решения проблемы помимо способа, которым я это делаю?(соблюдая 3 правила конечно)

1 Ответ

1 голос
/ 11 августа 2011

Ответ в соответствии с комментариями.Необходимая инструкция: xsl:template (вызывается путем применения соответствующих шаблонов).

Например, следующая таблица стилей дает тот же результат, что и ваша: 

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" indent="yes"/>

    <xsl:template match="/">
        <xsl:apply-templates select="school/faculty/area/name"/>
    </xsl:template>

    <xsl:template match="name">
        <xsl:call-template name="T1"/>
    </xsl:template>

    <xsl:template name="T1">
        <xsl:value-of select="concat(.,' (',string-length(.),')&#10;')"/>
    </xsl:template>

</xsl:stylesheet>
...