рисовать спрайт в растровые данные со странной маской - PullRequest
Новая
       27

рисовать спрайт в растровые данные со странной маской

1 голос
/ 14 апреля 2009

Я столкнулся со странным поведением при рисовании спрайта в BitmapData. Этот спрайт отлично смотрится при рисовании прямо на экране. Но когда этот спрайт рисуется в BitmapData, спрайт маскируется ... , но к этому спрайту не применяется такая маска!

Эту "плохую маску" можно выключать и включать ..., применяя / не применяя другую маску к спрайту, который я рисую. Эта маска не совпадает по форме и расположению с «плохой маской».

альтернативный текст http://img5.imageshack.us/img5/8310/masked.png

Мне интересно, если я делаю что-то не так или это ошибка? Я добавляю маски в порядке , описанном в документации . "Плохая маска", кажется, получает свои координаты от позиции спрайта, который я рисую (drawingSprite), относительно его родителей. 

package
{

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.Sprite;

import mx.core.UIComponent;

public class tmpa extends UIComponent
{

    public function tmpa( ):void
    {   var topSprite:Sprite = new Sprite();
        topSprite.x = 0;
        topSprite.y = 0;
        addChild( topSprite );

        var canvasSprite:Sprite = new Sprite();
        canvasSprite.x = 5;
        canvasSprite.y = 35;
        topSprite.addChild( canvasSprite );

        var drawingSprite:Sprite = new Sprite();
        canvasSprite.addChild( drawingSprite );

        var maskSp:Sprite = new Sprite();
        maskSp.graphics.beginFill( 0xFFFFFF, 1 );
        maskSp.graphics.drawRect( 0, 0, 200, 200 );
        maskSp.graphics.endFill();

        //toggle these two lines of code
        canvasSprite.addChild( maskSp );
        drawingSprite.mask = maskSp;

        drawingSprite.graphics.beginFill( 0xFF0000, 1 );
        drawingSprite.graphics.drawRect( 0, 0, 200, 200 );
        drawingSprite.graphics.endFill();

        drawingSprite.graphics.beginFill( 0x00FF00, 1 );
        drawingSprite.graphics.drawCircle( 0, 0, 100 );
        drawingSprite.graphics.endFill();


        //a snapshot with default blue background
        var bmd:BitmapData = new BitmapData( 100, 100, false, 0x0000FF );
        bmd.draw( drawingSprite );
        var bm:Bitmap = new Bitmap( bmd );
        bm.x = 300;
        bm.y = 35;
        addChild( bm );
    }

}
}

<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" xmlns:a="*" width="100%" height="100%">
    <a:tmpa id="t" width="100%" height="100%" x="0" y="0" left="0" top="0"/>
</mx:Application>

1 Ответ

1 голос
/ 14 апреля 2009

Изменение маски при добавлении строк: 

canvasSprite.addChild( maskSp );
canvasSprite.mask = maskSp;

Решает проблему, поэтому, скорее всего, существует некоторая путаница с относительными координатными пространствами клипов. Я думаю, что вы должны держать свою маску на том же уровне, что и скрытый объект DisplayObject в вашем списке отображения, чтобы избежать путаницы.

...