как объединить строку с двумя различными разделителями с помощью xsl

Question

У меня есть XML

<main>
  <DATA_RECORD>
    <COMPONENT_SID>100</COMPONENT_SID>
    <GROUP_ID>1</GROUP_ID>
  </DATA_RECORD>
  <DATA_RECORD>
    <COMPONENT_SID>200</COMPONENT_SID>
    <GROUP_ID>1</GROUP_ID>
  </DATA_RECORD>
  <DATA_RECORD>
    <COMPONENT_SID>400</COMPONENT_SID>
    <GROUP_ID>1</GROUP_ID>
  </DATA_RECORD>
  <DATA_RECORD>
    <COMPONENT_SID>10</COMPONENT_SID>
    <GROUP_ID>2</GROUP_ID>
  </DATA_RECORD>
  <DATA_RECORD>
    <COMPONENT_SID>20</COMPONENT_SID>
    <GROUP_ID>2</GROUP_ID>
  </DATA_RECORD>
  <DATA_RECORD>
    <COMPONENT_SID>2</COMPONENT_SID>
    <GROUP_ID>3</GROUP_ID>
  </DATA_RECORD>
  <DATA_RECORD>
    <COMPONENT_SID>4</COMPONENT_SID>
    <GROUP_ID>3</GROUP_ID>
  </DATA_RECORD>
  <DATA_RECORD>
    <COMPONENT_SID>8</COMPONENT_SID>
    <GROUP_ID>3</GROUP_ID>
  </DATA_RECORD>
  <DATA_RECORD>
    <COMPONENT_SID>16</COMPONENT_SID>
    <GROUP_ID>3</GROUP_ID>
  </DATA_RECORD>
  </main>

Я бы хотел использовать xsl для разбора на другой XML. Выход будет

<comp value="100,200,400|10,20|2,4,8,16"/> 

, где component_sids принадлежали разным group_id, разделены "|" , Компоненты component_sids, принадлежащие одному и тому же идентификатору группы, должны быть объединены с "," Я использовал следующий xsl

<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:template match="/">
          <xsl:element name="comp">
             <xsl:attribute name="value">
                 <xsl:call-template name="join"> 
                        <xsl:with-param name="list" select="//DATA_RECORD[GROUP_ID=1]/COMPONENT_SID" /> 
                        <xsl:with-param name="separator" select="','" />                                             
                  </xsl:call-template> 
              </xsl:attribute>
        </xsl:element>
  </xsl:template>

   <xsl:template name="join"> 
    <xsl:param name="list" /> 
    <xsl:param name="separator"/>     
    <xsl:for-each select="$list"> 
      <xsl:value-of select="." /> 
      <xsl:if test="position() != last()"> 
        <xsl:value-of select="$separator" />         
      </xsl:if> 
    </xsl:for-each> 
  </xsl:template> 
</xsl:stylesheet>

Результат

<comp value="100,200,400"/>

Но я не мог понять, как разделить другие группы component_sid с помощью «|». Может ли кто-нибудь мне помочь?

Заранее спасибо

Answer 1

Решение XSLT 2.0 может быть сокращено до:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>

<xsl:template match="/">
  <xsl:variable name="vResult">
   <xsl:for-each-group select="*/*" group-by="GROUP_ID">
    <xsl:if test="not(position()=1)">|</xsl:if>
    <xsl:value-of select="current-group()/COMPONENT_SID" separator=","/>
   </xsl:for-each-group>
  </xsl:variable>

  <comp value="{$vResult}"/>
 </xsl:template>
</xsl:stylesheet>

Answer 2

I. Решение XSLT 1.0 :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:key name="kRecByGrId" match="DATA_RECORD"
                            use="GROUP_ID"/>

 <xsl:variable name="vGrIds" select=
 "/*/DATA_RECORD
      [generate-id()
      =
       generate-id(key('kRecByGrId', GROUP_ID)[1])
       ]
        /GROUP_ID
 "/>

 <xsl:template match="/">
   <xsl:variable name="vResult">
       <xsl:for-each select="$vGrIds">
        <xsl:if test="not(position()=1)">|</xsl:if>
        <xsl:apply-templates select=
          "key('kRecByGrId', .)/COMPONENT_SID"/>
       </xsl:for-each>
     </xsl:variable>

     <comp value="{$vResult}"/>
 </xsl:template>

 <xsl:template match="COMPONENT_SID">
      <xsl:if test="not(position()=1)">,</xsl:if>
      <xsl:value-of select="."/>
 </xsl:template>
</xsl:stylesheet>

при применении к предоставленному документу XML :

<main>
    <DATA_RECORD>
        <COMPONENT_SID>100</COMPONENT_SID>
        <GROUP_ID>1</GROUP_ID>
    </DATA_RECORD>
    <DATA_RECORD>
        <COMPONENT_SID>200</COMPONENT_SID>
        <GROUP_ID>1</GROUP_ID>
    </DATA_RECORD>
    <DATA_RECORD>
        <COMPONENT_SID>400</COMPONENT_SID>
        <GROUP_ID>1</GROUP_ID>
    </DATA_RECORD>
    <DATA_RECORD>
        <COMPONENT_SID>10</COMPONENT_SID>
        <GROUP_ID>2</GROUP_ID>
    </DATA_RECORD>
    <DATA_RECORD>
        <COMPONENT_SID>20</COMPONENT_SID>
        <GROUP_ID>2</GROUP_ID>
    </DATA_RECORD>
    <DATA_RECORD>
        <COMPONENT_SID>2</COMPONENT_SID>
        <GROUP_ID>3</GROUP_ID>
    </DATA_RECORD>
    <DATA_RECORD>
        <COMPONENT_SID>4</COMPONENT_SID>
        <GROUP_ID>3</GROUP_ID>
    </DATA_RECORD>
    <DATA_RECORD>
        <COMPONENT_SID>8</COMPONENT_SID>
        <GROUP_ID>3</GROUP_ID>
    </DATA_RECORD>
    <DATA_RECORD>
        <COMPONENT_SID>16</COMPONENT_SID>
        <GROUP_ID>3</GROUP_ID>
    </DATA_RECORD>
</main>

дает желаемый, правильный результат :

<comp value="100,200,400|10,20|2,4,8,16"/>

Объяснение

1. мюнхенский метод группировки - найти все различные значения GROUP_ID.

2. Простая логика для добавления элемента (или группы) к разделителю , если этот элемент (или группа) не первый.

II. Решение XSLT 2.0 :

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
  <xsl:variable name="vResult">
   <xsl:for-each-group select="*/*" group-by="GROUP_ID">
    <xsl:if test="not(position()=1)">|</xsl:if>
    <xsl:for-each select="current-group()/COMPONENT_SID">
      <xsl:if test="not(position()=1)">,</xsl:if>
      <xsl:value-of select="."/>
    </xsl:for-each>
   </xsl:for-each-group>
  </xsl:variable>

     <comp value="{$vResult}"/>
 </xsl:template>
</xsl:stylesheet>

при применении к тому же XML-документу (см. Выше), снова желаемый, правильный результат :

<comp value="100,200,400|10,20|2,4,8,16"/>

Объяснение

1. Использование <xsl:for-each-group>

2. Использование current-group()

3. Та же самая простая логика для предшествующего каждому элементу (или группе), который не является первым, с соответствующим разделителем.