Adobe AIR - сохранить изображение на жестком диске - PullRequest
Новая
       1

Adobe AIR - сохранить изображение на жестком диске

4 голосов
/ 10 октября 2011

Я нашел приведенный ниже фрагмент, чтобы сохранить изображение в определенную папку с помощью Adobe AIR.

Как изменить, чтобы сначала появлялось "Сохранить как" окно ОС?(Таким образом, пользователи могут выбрать, где сохранить изображение на жестком диске) 

var arrBytes:ByteArray = PNGEncoder.encode(bmd);
    var file:File = File.desktopDirectory.resolvePath(folderName + "/" + fileName + fileNum + ".png");
    var fileStream:FileStream = new FileStream();
    //
    fileStream.open(file, FileMode.WRITE);
    fileStream.writeBytes(arrBytes);
    fileStream.close();

Спасибо.

1 Ответ

5 голосов
/ 10 октября 2011

Использовать File.browseForSave : 

import flash.filesystem.*;
import flash.events.Event;
import flash.utils.ByteArray;

var imgBytes:ByteArray = PNGEncoder.encode(bmd);
var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForSave("Save As");
    docsDir.addEventListener(Event.SELECT, saveData);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function saveData(event:Event):void 
{
    var newFile:File = event.target as File;
    if (!newFile.exists) // remove this 'if' if overwrite is OK.
    {
        var stream:FileStream = new FileStream();
        stream.open(newFile, FileMode.WRITE);
        stream.writeBytes(imgBytes);
        stream.close();
    } 
    else trace('Selected path already exists.');
}

Инструкция всегда твой друг :)

Кстати, я вижу, вы здесь относительно новы - добро пожаловать в StackExchange! Если мой ответ окажется полезным, обязательно выберите его в качестве ответа.

...