Как использовать Moose для добавления вспомогательных функций для атрибутов массива? - PullRequest
Новая
       3

Как использовать Moose для добавления вспомогательных функций для атрибутов массива?

7 голосов
/ 28 апреля 2011

Боюсь, это основной вопрос. Посмотрите на следующий код. Я хотел бы знать, есть ли способ объявить атрибут slices таким образом, чтобы избежать шаблонов get_slices и add_slice. 

package Gurke;
use Moose;

has slices => is => 'rw', isa => 'ArrayRef[Str]', default => sub { [] };

sub get_slices { return @{ $_[0]->slices } }

sub add_slice {
    my( $self, $slice ) = @_;
    push @{ $self->slices }, $slice;
    return;
}

no Moose;
__PACKAGE__->meta->make_immutable;

package main; # now a small test for the above package
use strict;
use warnings;
use Test::More;
my $gu = Gurke->new;
$gu->add_slice( 'eins' );
$gu->add_slice( 'zwei' );
$gu->add_slice( 'drei' );
my @sl = $gu->get_slices;
is shift @sl, 'eins';
is shift @sl, 'zwei';
is shift @sl, 'drei';
done_testing;

Спасибо!

1 Ответ

10 голосов
/ 28 апреля 2011

Я новичок в Moose, но думаю, вам нужно это: 

has slices =>
    is => 'rw',
    isa => 'ArrayRef[Str]',
    default => sub { [] },
    traits  => ['Array'],
    handles => {
        add_slice  => 'push',
        get_slices => 'elements',
    },
;
...