DateTimePicker контролирует использование в конкретном сценарии

Question

Этот вопрос относится к конкретной функциональности, которую клиент запросил для приложения, которое я разрабатываю. По сути, клиент хочет, чтобы DateTimePicker запрашивал вопрос после того, как была выбрана дата.

Это звучит просто, однако у меня возникают трудности с выполнением этой простой задачи.

1. Если я предложу OnCloseUp - записи клавиатуры не будут выполнять это событие
2. Если я предложу OnValueChanged - Событие срабатывает каждый раз, когда дата изменено
3. Если я подскажу OnLeave - Событие несколько срабатывает. Не срабатывает когда например, нажата панель инструментов. Я хотел бы избежать этого метода, так как он срабатывает только после того, как пользователь отходит от элемента управления.

Так что, в основном, я пытаюсь придумать лучший способ предложить пользователю ПОСЛЕ того, как он выберет дату из элемента управления dateTimePicker.

У меня также нет проблем с созданием пользовательского элемента управления. Я начал делать один, так как мне также нужно было разрешить значения NULL.

Answer 1

«Выбрать дату» означает:

1. Выберите дату с помощью мыши или
2. Введите / измените дату с помощью клавиатуры, затем переместите фокус на другой элемент управления.

Итак, как насчет комбинации OnCloseUp и OnValidate / OnLeave?

Начните с просмотра OnValueChanged событий. Установите измененный флаг, если один выстрелит.

Если они выбирают с помощью мыши, вы можете вызвать приглашение с помощью OnCloseUp и сбросить ваш измененный флаг. Затем снова посмотрите на OnValueChanged события.

Когда срабатывает OnValidate или OnLeave и ваш флаг установлен (предположительно, после изменения даты с помощью клавиатуры), затем вызовите приглашение.

Answer 2

Я бы использовал событие OnValueChanged. После того, как они меняют значение, задайте вопрос. Если они ответят неправильно (Пример - Q: Вы уверены? A: Нет.), Затем сбросьте указатель даты и верните фокус на него.

Этот пример немного грязный, но работает.

Private is_reset As Boolean = False
Private Sub DateTimePicker1_ValueChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles DateTimePicker1.ValueChanged

    Dim answer As Integer
    If Not is_reset Then
        answer = MsgBox("Are you Sure?", MsgBoxStyle.YesNo)
        is_reset = False
    End If

    If answer = MsgBoxResult.No Then
        is_reset = True
        DateTimePicker1.Value = Now
        DateTimePicker1.Select()
    End If

Answer 3

В итоге я написал собственный элемент управления для правильной обработки. Я создал текстовое поле с кнопкой и также добавил элемент управления MonthCalendar.

Кнопка textbox + открывает элемент управления MonthCalendar. Единственный способ выбрать дату и время - через MonthCalendar. Вы не можете выбрать из текстового поля. Я также создал пользовательское событие, которое срабатывает при выборе даты. Работает отлично. Код ниже:

Public Class CustomDatePicker

  'Variables
  Friend WithEvents cal As MonthCalendar
  Private _isCalendarVisible As Boolean = False
  Private _currentSelectedDate As DateTime = Nothing

  'Events
  Public Event OnDateTimeSet(ByVal sender As Object, ByVal dateValue As DateTime)
  Public Event OnDateCleared(ByVal sender As Object)

  'Constructor
  Public Sub New()
    InitializeComponent()
  End Sub

  'Onload
  Private Sub CustomDatePicker_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
    'Initially setup calendar
    cal = New MonthCalendar
    cal.Name = "Calendar"
    cal.MaxSelectionCount = 1
    cal.BringToFront()
    cal.Location = New Point(Me.Location.X + 5, Me.Location.Y + 25)
    Me.Parent.Controls.Add(cal)
    cal.Hide()
    _isCalendarVisible = False
  End Sub

  'Returns the currently selected date from the TextBox field
  Public ReadOnly Property CurrentSelectedDate()
    Get
      Return _currentSelectedDate
    End Get
  End Property

  'Display calendar
  Private Sub ShowCalendar()

    'Close any other custom date controls that are open on the parent form
    Dim cont As Control
    For Each cont In Parent.Controls
      If (cont.GetType().Name = "CustomDatePicker") Then
        CType(cont, CustomDatePicker).HideCalendar()
      End If
    Next

    'display the calendar
    If Not (_isCalendarVisible) Then
      tbxSelectedDate.BackColor = Color.Cornsilk
      cal.BringToFront()
      cal.Show()
      cal.Focus()
      _isCalendarVisible = True
      btnCalendarToggle.Checked = True
    End If

  End Sub

  'Hide the Calendar
  Private Sub HideCalendar()
    If (_isCalendarVisible) Then
      tbxSelectedDate.BackColor = Color.White
      cal.Hide()
      _isCalendarVisible = False
      btnCalendarToggle.Checked = False
      tbxSelectedDate.Focus()
    End If
  End Sub

  'Display the selected datetime into the textbox
  Private Sub SetDateTime()
    Me.tbxSelectedDate.Text = FormatDateTime(cal.SelectionRange.Start, DateFormat.LongDate)
    _currentSelectedDate = FormatDateTime(cal.SelectionRange.Start, DateFormat.LongDate)
    RaiseEvent OnDateTimeSet(Me, _currentSelectedDate)
  End Sub

  'Event when selection is made in the Calendar
  Private Sub Calendar_Selection(ByVal sender As System.Object, ByVal e As System.Windows.Forms.DateRangeEventArgs) Handles cal.DateSelected
    SetDateTime()
    HideCalendar()
  End Sub

  'Handle the keyboard events associated with the calendar control
  Private Sub Calendar_KeyPress(ByVal sender As System.Object, ByVal e As System.Windows.Forms.KeyPressEventArgs) Handles cal.KeyPress
    If e.KeyChar = ChrW(Keys.Return) Then
      SetDateTime()
      HideCalendar()
    ElseIf e.KeyChar = ChrW(Keys.Escape) Then
      HideCalendar()
    End If
  End Sub

  'Handles keypresses on the textbox field
  Private Sub tbxSelectedDate_KeyUp(ByVal sender As System.Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles tbxSelectedDate.KeyUp
    If (e.KeyCode = Keys.Down) Then
      ShowCalendar()
    ElseIf (e.KeyCode = Keys.Delete) Then
      tbxSelectedDate.Text = ""
    End If
  End Sub

  'Show the calendar when button is clicked
  Private Sub btnCalendarToggle_MouseUp(ByVal sender As System.Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles btnCalendarToggle.MouseUp
    ToggleCalendar()
  End Sub

  'Show the calendar when button is 'clicked' via ENTER on keyboard
  Private Sub btnCalendarToggle_KeyPress(ByVal sender As System.Object, ByVal e As System.Windows.Forms.KeyPressEventArgs) Handles btnCalendarToggle.KeyPress
    If e.KeyChar = ChrW(Keys.Return) Then
      ToggleCalendar()
    End If
  End Sub

  'Toggle calender.  If on, turn off.  If off, turn on.
  Private Sub ToggleCalendar()
    If Not (_isCalendarVisible) Then
      ShowCalendar()
      btnCalendarToggle.Checked = True
    Else
      HideCalendar()
      btnCalendarToggle.Checked = False
    End If
  End Sub

  'When textbox value is changed, check to see if it was cleared.  If cleared, raiseevent.
  Private Sub tbxSelectedDate_TextChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles tbxSelectedDate.TextChanged
    If (tbxSelectedDate.Text = "") Then
      _currentSelectedDate = Nothing
      RaiseEvent OnDateCleared(Me)
    End If
  End Sub