Открыть любой файл в заметке?

Question

В блокноте вы можете открыть любой файл, и он будет отображать необработанные данные внутри.

Я хотел бы сделать это в TMemo, но изо всех сил пытался выяснить, как это сделать.

Мне удалось найти этот код здесь.

Я изменил его в функцию и немного изменил для моих целей:

function OpenBinaryFile(var Data; Count: Cardinal): string;
var
  Line: string[80];
  i: Cardinal;
  P: PAnsiChar;
  nStr: string[4];
  SL: TStringList;
const
  posStart = 1;
  binStart = 7;
  ascStart = 57;
begin
  P := @Data;
  Line := '';

  SL := TStringList.Create;
  try
    for i := 0 to Count - 1 do
    begin
      if (i mod 16) = 0 then
      begin
        if Length(Line) > 0 then
          SL.Add(Trim(Line));

        FillChar(Line, SizeOf(Line), ' ');
        Line[0] := Chr(72);
      end;

    if P[i] >= ' ' then
      Line[i mod 16 + ascStart] := P[i]
    else
      Line[i mod 16 + ascStart] := '.';
    end;

    SL.Add(Trim(Line));

    Result := SL.Text;
 finally
    SL.Free;
  end;
end;

Это работает, но это толькоотображается в фиксированном количестве символов в строке, например:

Что мне нужно изменить, чтобы он заполнял все заметки так же, как Блокнот?

Answer 1

Ну, это тест if (i mod 16) = 0, который усекает строки до 16 символов.

Я считаю, что Блокнот делает то же самое, что и этот код:

var
  i: Integer;
  s: AnsiString;
  Stream: TFileStream;
begin
  Stream := TFileStream.Create(FileName, fmOpenRead);
  try
    SetLength(s, Stream.Size);
    if Stream.Size>0 then
      Stream.ReadBuffer(s[1], Stream.Size);
  finally
    Stream.Free;
  end;
  for i := 1 to Length(s) do
    if s[i]=#0 then
      s[i] := ' ';
  Memo1.Text := s;
end;

замените непечатаемые символы на '.', тогда вы можете легко сделать это, изменив приведенный выше код следующим образом:

if s[i]<#32 then
  s[i] := '.';

Answer 2

TStrings стал TEncoding -осведомленным в D2009.По умолчанию TStrings.LoadFrom...() будет использовать TEncoding.Default, если не указано иное.Я бы предложил реализовать пользовательский TEncoding производный класс, который читает / записывает необработанные 8-битные данные, например:

type
  TRawEncoding = class(TEncoding)
  protected
    function GetByteCount(Chars: PChar; CharCount: Integer): Integer; override;
    function GetBytes(Chars: PChar; CharCount: Integer; Bytes: PByte; ByteCount: Integer): Integer; override;
    function GetCharCount(Bytes: PByte; ByteCount: Integer): Integer; override;
    function GetChars(Bytes: PByte; ByteCount: Integer; Chars: PChar; CharCount: Integer): Integer; override;
  public
    constructor Create;
    function GetMaxByteCount(CharCount: Integer): Integer; override;
    function GetMaxCharCount(ByteCount: Integer): Integer; override;
    function GetPreamble: TBytes; override;
  end;

.

constructor TRawEncoding.Create;
begin
  FIsSingleByte := True;
  FMaxCharSize := 1;
end;

function TRawEncoding.GetByteCount(Chars: PChar; CharCount: Integer): Integer;
begin
  Result := CharCount;
end;

function TRawEncoding.GetBytes(Chars: PChar; CharCount: Integer; Bytes: PByte; ByteCount: Integer): Integer;
var
  i : Integer;
begin
  Result := Math.Min(CharCount, ByteCount);
  for i := 1 to Result do begin
    // replace illegal characters > $FF
    if Word(Chars^) > $00FF then begin
      Bytes^ := Byte(Ord('?'));
    end else begin
      Bytes^ := Byte(Chars^);
    end;
    //advance to next char
    Inc(Chars);
    Inc(Bytes);
  end;
end;

function TRawEncoding.GetCharCount(Bytes: PByte; ByteCount: Integer): Integer;
begin
  Result := ByteCount;
end;

function TRawEncoding.GetChars(Bytes: PByte; ByteCount: Integer; Chars: PChar; CharCount: Integer): Integer;
var
  i : Integer;
begin
  Result := Math.Min(CharCount, ByteCount);
  for i := 1 to Result do begin
    Word(Chars^) := Bytes^;
    //advance to next char
    Inc(Chars);
    Inc(Bytes);
  end;
end;

function TRawEncoding.GetMaxByteCount(CharCount: Integer): Integer;
begin
  Result := CharCount;
end;

function TRawEncoding.GetMaxCharCount(ByteCount: Integer): Integer;
begin
  Result := ByteCount;
end;

function TRawEncoding.GetPreamble: TBytes;
begin
  SetLength(Result, 0);
end;

Затем вы можете использовать его следующим образом:

var
  Enc: TEncoding;
begin
  Enc := TRawEncoding.Create;
  try
    Memo1.Lines.LoadFromFile('filename', Enc);
  finally
    Enc.Free;
  end;
end;