Qmake создает файл .pc

Question

Кто-нибудь знает, может ли qmake создать файл .pc? Я нашел кого-то, кто сказал, что это может здесь: http://www.qtcentre.org/threads/24422-How-can-we-create-.pc-file-automatically. Но я попробовал это и получил те же результаты, что и человек, имеющий проблему в нижней части потока. Мне было интересно, знал ли кто-нибудь об этом.

TEMPLATE = lib
TARGET = proc_Model
QT += declarative dbus
CONFIG += qt plugin dbus create_pc
DESTDIR = /usr/lib/

OBJECTS_DIR = .obj
MOC_DIR = .moc


TARGET = $$qtLibraryTarget($$TARGET)

INCLUDEPATH += ../common 

# Input
SOURCES +=    ../common/proc_struct.cpp \
    listitem.cpp \
    listmodel.cpp \
    process.cpp \
    proc_if.cpp

HEADERS +=  ../common/proc_struct.h \
    listitem.h \
    listmodel.h \
    process.h \
    proc_if.h



headers.path= /usr/include/proc_Model
headers.files = ../common/proc_struct.h \
    listitem.h \
    listmodel.h \
    process.h \
    proc_if.h

target.path = /usr/lib



QMAKE_PKGCONFIG_NAME = proc_Model
QMAKE_PKGCONFIG_DESCRIPTION = Model that emits process info
QMAKE_PKGCONFIG_LIBDIR = $$target.path
QMAKE_PKGCONFIG_INCDIR = $$target.path
QMAKE_PKGCONFIG_DESTDIR = pkgconfig


INSTALLS+=headers target

Когда я делаю установку, я получаю следующий вывод:

install -m 755 -p "/usr/lib/libproc_Model.so" "/usr/lib/libproc_Model.so"
install: `/usr/lib/libproc_Model.so' and `/usr/lib/libproc_Model.so' are the same file
make: [install_target] Error 1 (ignored)
strip --strip-unneeded "/usr/lib/libproc_Model.so"
install -m 644 -p "/usr/lib/pkgconfig/proc_Model.pc" "/usr/lib/pkgconfig/proc_Model.pc"
install: cannot stat `/usr/lib/pkgconfig/proc_Model.pc': No such file or directory
make: [install_target] Error 1 (ignored)

Answer 1

Я сделал полный пример здесь: https://github.com/pvanhoof/dir-examples/blob/master/qmake-example/src/libs/qmake-example/qmake-example.pro

## We get the PREFIX, MAJOR_VERSION, MINOR_VERSION and PATCH_VERSION
## from this project-wide include

include(../../../qmake-example.pri)

## We will use the standard lib template of qmake

TEMPLATE = lib

## We need to set VERSION to a semver.org version for compile_libtool

VERSION = $${MAJOR_VERSION}"."$${MINOR_VERSION}"."$${PATCH_VERSION}

## According https://autotools.io/libtool/version.html, section 4.3
## we should have as target-name the API version in the library's name

TARGET = qmake-example-$${MAJOR_VERSION}"."$${MINOR_VERSION}

## We will write a define in config.h for access to the semver.org
## version as a double quoted string

QMAKE_SUBSTITUTES += config.h.in

## Our example happens to use QDebug, so we need QtCore here

QT = core

## This is of course optional

CONFIG += c++14

## We will be using libtool style libraries

CONFIG += compile_libtool
CONFIG += create_libtool

## These will create a pkg-config .pc file for us

CONFIG += create_pc create_prl no_install_prl

## Project sources

SOURCES = \
    qmake-example.cpp

## Project headers

HEADERS = \
    qmake-example.h

## We will install the headers in a API specific include path

headers.path = $${PREFIX}/include/qmake-example-$${MAJOR_VERSION}"."$${MINOR_VERSION}

## Here will go all the installed headers

headers.files = $${HEADERS}

## Here we will install the library to
target.path = $${PREFIX}/lib

## This is the configuration for generating the pkg-config file

QMAKE_PKGCONFIG_NAME = $${TARGET}
QMAKE_PKGCONFIG_DESCRIPTION = An example that illustrates how to do it right with qmake

# This is our libdir
QMAKE_PKGCONFIG_LIBDIR = $$target.path

# This is where our API specific headers are
QMAKE_PKGCONFIG_INCDIR = $$headers.path
QMAKE_PKGCONFIG_DESTDIR = pkgconfig
QMAKE_PKGCONFIG_PREFIX = $${PREFIX}
QMAKE_PKGCONFIG_VERSION = $$VERSION

## Installation targets (the pkg-config seems to install automatically)

INSTALLS += headers target

Answer 2

Согласно исходному коду qmake, вы должны добавить:

CONFIG += create_prl no_install_prl

create_pc добавляет правило для целевого файла .pc только в make-файл с помощью команды "qmake -prl", и эта команда создает файл .pc, только если опция create_prl присутствует.

no_install_prl предотвращает установку ненужного файла .prl, созданного create_prl, в $ {target.path}.