Applescript - Как получить каждую строку буфера обмена, разделенную символом новой строки, и выполнить действие с каждой строкой? - PullRequest
Новая
       23

Applescript - Как получить каждую строку буфера обмена, разделенную символом новой строки, и выполнить действие с каждой строкой?

2 голосов
/ 16 декабря 2011

Я пытаюсь изменить appleScript, который принимает текстовый файл и создает новую задачу с каждой строкой текстового файла: 

set myFile to (choose file with prompt "Select a file to read:")
open for access myFile

set fileContents to read myFile using delimiter {linefeed}
close access myFile

tell application "Things"

    repeat with currentLine in reverse of fileContents

        set newToDo to make new to do ¬
            with properties {name:currentLine} ¬
            at beginning of list "Next"
        -- perform some other operations using newToDo

    end repeat

end tell

Вместо этого я бы хотел просто использовать буфер обмена в качестве источника данных, чтобы мне не приходилось каждый раз создавать и сохранять текстовый файл, есть ли способ загрузить буфер обмена и для каждой новой строки , выполнить функцию newToDo?

Пока это моя попытка, но она, похоже, не работает и помещает весь буфер обмена в одну строку. Кажется, я не могу найти правильный разделитель. 

try
    set oldDelims to AppleScript's text item delimiters -- save their current state
    set AppleScript's text item delimiters to {linefeed} -- declare new delimiters

    set listContents to get the clipboard
    set delimitedList to every text item of listContents

    tell application "Things"
        repeat with currentTodo in delimitedList
            set newToDo to make new to do ¬
                with properties {name:currentTodo} ¬
                at beginning of list "Next"
            -- perform some other operations using newToDo
        end repeat
    end tell

    set AppleScript's text item delimiters to oldDelims -- restore them
on error
    set AppleScript's text item delimiters to oldDelims -- restore them in case something went wrong
end try

EDIT: С помощью ответа ниже код невероятно прост! 

set listContents to get the clipboard
set delimitedList to paragraphs of listContents

tell application "Things"
    repeat with currentTodo in delimitedList
        set newToDo to make new to do ¬
            with properties {name:currentTodo} ¬
            at beginning of list "Next"
        -- perform some other operations using newToDo
    end repeat
end tell

1 Ответ

3 голосов
/ 16 декабря 2011

В Applescript есть команда под названием "параграфы", которая очень хороша для определения, что такое разделитель строк.Как таковой, попробуйте.Обратите внимание, что при таком подходе вам не понадобятся «разделители текстовых элементов». 

set listContents to get the clipboard
set delimitedList to paragraphs of listContents

Обратите внимание: если вы хотите использовать свой код, это правильный способ получить символ перевода строки.. 

set LF to character id 10
...