Как автоматически сделать org-mobile-push org-mobile pull в emacs

Question

Поскольку я использую org-mode для отслеживания своего списка задач в emacs, мне нравится приложение для iPhone: MobileOrg, с его помощью я могу получать доступ к своему списку задач весь день.

Но вот проблема:

Мне нужно вручную org-mobile-push перенести изменения из локального файла на мобильный телефон через Dropbox, и org-mobile-pull отменить изменения, сделанные телефоном.

Как сделать это автоматически? Как добавление некоторых рецептов в файл dotemacs.

Answer 1

Добавьте эти две строки в файл emacs с точкой:

(add-hook 'after-init-hook 'org-mobile-pull)
(add-hook 'kill-emacs-hook 'org-mobile-push) 

С ними он автоматически извлекает изменения при запуске emacs и отправляет изменения до выхода из emacs.

- Обновление

Если вы никогда не выйдете из Emacs, это решение может не сработать для вас.Итак, другое решение, использующее таймер простоя

;; moble sync
(defvar org-mobile-sync-timer nil)
(defvar org-mobile-sync-idle-secs (* 60 10))
(defun org-mobile-sync ()
  (interactive)
  (org-mobile-pull)
  (org-mobile-push))
(defun org-mobile-sync-enable ()
  "enable mobile org idle sync"
  (interactive)
  (setq org-mobile-sync-timer
        (run-with-idle-timer org-mobile-sync-idle-secs t
                             'org-mobile-sync)));
(defun org-mobile-sync-disable ()
  "disable mobile org idle sync"
  (interactive)
  (cancel-timer org-mobile-sync-timer))
(org-mobile-sync-enable)

Я только что обнаружил, что это то же самое, что и ответ ниже, поэтому, если вы предпочитаете решение таймера простоя, пожалуйста, наберите tkf's answer .

Answer 2

У меня есть что-то вроде этого в настройках Emacs, чтобы делать push и pull, когда я вдали от компьютера.

(defvar my-org-mobile-sync-timer nil)

(defvar my-org-mobile-sync-secs (* 60 20))

(defun my-org-mobile-sync-pull-and-push ()
  (org-mobile-pull)
  (org-mobile-push)
  (when (fboundp 'sauron-add-event)
    (sauron-add-event 'my 3 "Called org-mobile-pull and org-mobile-push")))

(defun my-org-mobile-sync-start ()
  "Start automated `org-mobile-push'"
  (interactive)
  (setq my-org-mobile-sync-timer
        (run-with-idle-timer my-org-mobile-sync-secs t
                             'my-org-mobile-sync-pull-and-push)))

(defun my-org-mobile-sync-stop ()
  "Stop automated `org-mobile-push'"
  (interactive)
  (cancel-timer my-org-mobile-sync-timer))

(my-org-mobile-sync-start)

Альтернативой является добавление следующего в работу cron (я нашел это здесь https://github.com/matburt/mobileorg-android/wiki/Scripting/):

emacs --batch --load ~/.emacs --eval "(org-mobile-pull)" --eval "(org-mobile-push)"

Answer 3

Этот код взят из http://kenmankoff.com/2012/08/17/emacs-org-mode-and-mobileorg-auto-sync/, с изменением пары деталей.Вам необходимо настроить переменные в начале.Этот код будет

• Проверять каждые 30 секунд, синхронизирована ли MobileOrg, и если да, то

  • Извлечь из MobileOrg.

  • Нажмите дляMobileOrg.

    Это необходимо для обновления представлений повестки дня в MobileOrg.При таком поведении вы можете быть вдали от своего компьютера, обновлять некоторые вещи в MobileOrg, синхронизировать, ждать 30 секунд, снова синхронизироваться, и ваш мобильный вид повестки дня будет обновлен.

• При каждом сохранении файла org
  • Проверьте, предполагается ли синхронизировать сохраненный файл org с MobileOrg, и если да, то
    • Подождите, пока пользователь не перейдет в режим ожидания
    • Нажмитена MobileOrg

Код для вашего файла .emacs:

(require 'org-mobile)
;; Configure these two variables
(setq org-mobile-inbox-for-pull "~/Dropbox/org/mobile.org" 
      org-mobile-directory "~/Dropbox/MobileOrg")
(require 'gnus-async) 
;; Define a timer variable
(defvar org-mobile-push-timer nil
  "Timer that `org-mobile-push-timer' used to reschedule itself, or nil.")
;; Push to mobile when the idle timer runs out
(defun org-mobile-push-with-delay (secs)
   (when org-mobile-push-timer
    (cancel-timer org-mobile-push-timer))
  (setq org-mobile-push-timer
        (run-with-idle-timer
         (* 1 secs) nil 'org-mobile-push)))
;; After saving files, start an idle timer after which we are going to push 
(add-hook 'after-save-hook 
 (lambda () 
   (if (or (eq major-mode 'org-mode) (eq major-mode 'org-agenda-mode))
     (dolist (file (org-mobile-files-alist))
       (if (string= (expand-file-name (car file)) (buffer-file-name))
           (org-mobile-push-with-delay 10))))))
;; watch mobileorg.org for changes, and then call org-mobile-pull
(defun org-mobile-install-monitor (file secs)
  (run-with-timer
   0 secs
   (lambda (f p)
     (unless (< p (second (time-since (elt (file-attributes f) 5))))
       (org-mobile-pull)
       (org-mobile-push)))
   file secs))
(defvar monitor-timer (org-mobile-install-monitor (concat org-mobile-directory "/mobileorg.org") 30)
  "Check if file changed every 30 s.")

Answer 4

В качестве побочного решения, аналогичного Sandeep C's

;; for Emacs 24.3.1 insert next line
(require 'cl)  
;; automatically org-mobile-push on save of a file
(add-hook 
 'after-save-hook 
 (lambda ()
   (let (
         (org-filenames (mapcar 'file-name-nondirectory (directory-files org-directory))) ; list of org file names (not paths)
         (filename (file-name-nondirectory buffer-file-name)) ; list of the buffers filename (not path)
         )
     (if (find filename org-filenames :test #'string=)
         (org-mobile-push)        
       )
     )
   )
)

Answer 5

Я использую этот код elisp из gist на моем init.el, и он работает довольно хорошо, за исключением того, что в него не встроен org-mobile-pull.

Answer 6

Вы также можете нажать сразу после сохранения заметки, например:

(add-hook 
  'after-save-hook 
  (lambda () 
     (if (string= buffer-file-name "<path to my notes.org>") 
        (org-mobile-push)
     )
  ))

Answer 7

Я решил просто нажать при сохранении, поэтому я добавил это в мой файл инициализации emacs:

(defun org-mobile-push-on-save ()
  "Used in `after-save-hook'."
  (when (memq this-command '(save-buffer save-some-buffers))
    (org-mobile-push)))

(add-hook 'org-mode-hook
          (lambda ()
            (add-hook 'after-save-hook 'org-mobile-push-on-save nil 'make-local)))

В двух словах, он добавляет ловушку после сохранения в буферы режима org.

Больше информации о коде:

• https://emacs.stackexchange.com/a/14476/12694
• https://stackoverflow.com/a/6141681/45881

Для автоматического извлечения, таймер, как и в других ответах, вероятно, является хорошим способом.