Как нарисовать текст водяного знака, контур которого красный, а внутренний - серый, используя iTextSharp - PullRequest
Новая
       24

Как нарисовать текст водяного знака, контур которого красный, а внутренний - серый, используя iTextSharp

0 голосов
/ 20 октября 2011

Как нарисовать текст водяного знака, контур которого красный, а внутренний - серый, используя iTextSharp

1 Ответ

3 голосов
/ 20 октября 2011

Если вы используете водяной знак, я предполагаю, что вы говорите о PdfStamper. Если это так, то после получения необработанного PdfContentByte с использованием либо GetOverContent(), либо GetUnderContent() вам нужно установить только пару свойств.

  • PdfContentByte.SetLineWidth(single) - установить толщину хода
  • PdfContentByte.SetColorFill(BaseColor.GRAY) - установить цвет заливки. Вы также можете использовать любой другой цветовой метод, например SetRGBColorFill() или SetCMYKColorFill()
  • PdfContentByte.SetColorStroke(BaseColor.RED) - установить цвет обводки
  • PdfContentByte.SetTextRenderingMode(PdfContentByte.TEXT_RENDER_MODE_FILL_STROKE) - отметка, что вы хотите, чтобы текст рисовался как с заливкой, так и с обводкой

Ниже представлено полнофункциональное приложение WinForms, предназначенное для iTextSharp 5.1.1.0, которое объединяет все это. Вы должны быть в состоянии переместить это в ASP.Net довольно легко, а также преобразовать его в C # при необходимости. 

Option Explicit On
Option Strict On

Imports iTextSharp.text
Imports iTextSharp.text.pdf
Imports System.IO

Public Class Form1

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        ''//Our sample files
        Dim InputFile = Path.Combine(Environment.GetFolderPath(Environment.SpecialFolder.Desktop), "Test.pdf")
        Dim OutputFile = Path.Combine(Environment.GetFolderPath(Environment.SpecialFolder.Desktop), "Test_W_Watermark.pdf")

        ''//Create our input file to watermark later, nothing special here
        Using FS As New FileStream(InputFile, FileMode.Create, FileAccess.Write, FileShare.Read)
            Using Doc As New Document(PageSize.LETTER)
                Using W = PdfWriter.GetInstance(Doc, FS)
                    Doc.Open()

                    Doc.Add(New Paragraph("This is a test"))

                    Doc.Close()
                End Using
            End Using
        End Using


        ''//Watermark the file that we create above

        ''//Bind a reader to our input file
        Dim R As New PdfReader(InputFile)
        ''//Create our output file stream
        Using FS As New FileStream(OutputFile, FileMode.Create, FileAccess.Write, FileShare.Read)
            ''//Bind a stamper to our output file stream
            Using stamper As New PdfStamper(R, FS)
                ''//Grab the raw content byte to draw with
                Dim cb = stamper.GetOverContent(1)

                ''//Flag that we are starting text commands
                cb.BeginText()

                ''//Set the stroke width
                cb.SetLineWidth(2)

                ''//Set the fill (inner) color for the font
                cb.SetColorFill(BaseColor.GRAY)

                ''//Set the stroke (outer) color for the font
                cb.SetColorStroke(BaseColor.RED)

                ''//Flag that when drawing text the system should use both a fill and a stroke
                cb.SetTextRenderingMode(PdfContentByte.TEXT_RENDER_MODE_FILL_STROKE)

                ''//Set a font to draw with
                cb.SetFontAndSize(BaseFont.CreateFont(BaseFont.HELVETICA, BaseFont.CP1252, BaseFont.EMBEDDED), 50)

                ''//Tell the system to start drawing at the center of the first page
                cb.SetTextMatrix(R.GetPageSize(1).Width / 2, R.GetPageSize(1).Height / 2)

                ''//Draw the actual text
                cb.ShowText("Hello")

                ''//Flag that we are done drawing text
                cb.EndText()
            End Using
        End Using
        Me.Close()
    End Sub
End Class
...