Управление пользовательским табличным представлением в Mathematica - PullRequest
Новая
       44

Управление пользовательским табличным представлением в Mathematica

2 голосов
/ 13 июня 2011

Принимая во внимание следующий пример данных: 

data ={
       {"a", "b", "c", "d", "e"},
       {1, 2, 3, 4, 5},
       {11, 12, 13, 14, 15}, 
       {21, 22, 23, 24, 25}
      };

И следующую функцию для создания настраиваемого табличного представления:

(и вы можетеобратитесь к Расширенное решение Mr.Wizard для настраиваемых табличных представлений . В настоящее время я также буду манипулировать предложенными им опциями) 

DataSampleX[data_, linesNumber_, range1_, range2_, color1_, color2_, color3_] :=

Grid[
 Join[
      {Range[range1, range2]}, {Map[Rotate[Text[#], 90 Degree] &,
       data[[1, range1 ;; range2]]]}, 
       data[[2 ;; linesNumber, range1 ;; range2]]
     ],
       Background    -> {{{{color1, color2}}, {1 -> color3}}},
       Dividers      -> {All, {1 -> True, 2 -> True, 3 -> True,0 -> True}},
       ItemSize      -> {1 -> Automatic, Automatic},
       Alignment     -> Top,
       Frame         -> True,
       FrameStyle    -> Thickness[2],
       ItemStyle     -> {Automatic, Automatic, 
                        {{1, 1}, {1, Length[data]}} ->Directive[FontSize -> 
                        15, Black, Bold]}
    ];

Я хотел бы использовать Manipulate или Dynamic для отображениячасти моих данных, используя выше.Это выбор диапазона столбца, который я хочу отобразить, количество отображаемых строк и цветов.

Ниже моя незаконченная попытка.

PopupMenu[Dynamic[range1], Range[1, Length@data[[1]] - 1, 1]]
PopupMenu[Dynamic[range2], Range[2, Length@data[[1]], 1]]
PopupMenu[Dynamic[linesNumber], Range[2, Length@data[[All, 1]] - 1, 1]]
Dynamic[DataSampleX[data, linesNumber, range1, range2, LightBlue, 
LightGray, LightYellow]]

enter image description here

enter image description here

Как я могу использовать setter для обновления значения цвета?

Возможно ли на самом деле иметьэто в окне «Манипулирование»?

Любые другие предложения, чтобы сделать этот эффектный внешний вид хорошим, приветствуются.

- РЕДАКТИРОВАТЬ: Что я могу сделать сейчас, благодаря решению Велисария ниже:

enter image description here

1 Ответ

2 голосов
/ 13 июня 2011

Попробуйте что-то вроде: 

colsel = (#->Graphics[{#, Disk[]},ImageSize -> 15])& /@ColorData[1, "ColorList"];
s[x_] := Style[x, Black, Bold, 12];
ct = ControlType -> PopupMenu;

Manipulate[
 DataSampleX[data, linesNumber, range1, range2, color1, color2, color3],
 Row[{
   Column[{
    Control@{{range1,      1, s@"Range1"}, Range[1, Length@data[[1]] - 1],  ct}, 
    Control@{{range2,      2, s@"Range2"}, Range[2, Length@data[[1]] - 1],  ct}, 
    Control@{{linesNumber, 2, s@"Lines"},  Range[2,Length@data[[All, 1]]-1],ct}}],
   Spacer[20],
   Column[{
     Control@{{color1, colsel[[1, 1]], s@"Color 1"}, colsel, ct}, 
     Control@{{color2, colsel[[2, 1]], s@"Color 2"}, colsel, ct}, 
     Control@{{color3, colsel[[3, 1]], s@"Color 3"}, colsel, ct}}]
 }]]

enter image description here

...