FLASH - добавленное пользователем / преобразованное текстовое поле

Question

Привет, мне было интересно, как я могу использовать текстовое поле, в котором пользователь может изменять размеры, щелкая и перетаскивая его во Flash?

т.е. фильм будет показывать текстовое поле с ручками преобразования и в зависимости от того, насколько широко или высоко он меняет перенос слов.

Возможно ли это? Ура, Том

Answer 1

Вот пример:

import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.text.TextField;

var textfield:TextField;
var handle:Sprite;

textfield = new TextField();
textfield.wordWrap = true;
textfield.border = true;
textfield.background = true;
textfield.text = "lorem ipsum dolor sit amet"

handle = new Sprite();
handle.graphics.beginFill(0x000000);
handle.graphics.drawRect(0, 0, 10, 10);
handle.graphics.endFill();

handle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
handle.x = textfield.x + textfield.width;
handle.y = textfield.y + textfield.height;

addChild(textfield);
addChild(handle);

function mouseDownHandler(event:MouseEvent):void
{
    handle.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
    handle.addEventListener(Event.ENTER_FRAME, frameHandler);
    handle.startDrag(false);
}

function mouseUpHandler(event:MouseEvent):void
{
    handle.removeEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
    handle.removeEventListener(Event.ENTER_FRAME, frameHandler);
    handle.stopDrag();
}

function frameHandler(event:Event):void
{
    textfield.width = handle.x - textfield.x;
    textfield.height = handle.y - textfield.y;
}