XSLT - функция документа и сопоставление для отображения - PullRequest
Новая
       5

XSLT - функция документа и сопоставление для отображения

0 голосов
/ 25 марта 2011

Вот мой пользователь xml: (users.xml) 

<?xml version="1.0"?>
<a:class xmlns:a="a">
  <a:users>
   <a:user>User1</a:user>
   <a:userid>9901</a:userid>
  </a:users>
   <a:users>
   <a:user>User2</a:user>
   <a:userid>9902</a:userid>
  </a:users>
  <a:users>
   <a:user>User3</a:user>
   <a:userid>9903</a:userid>
  </a:users>  
   <a:users>
   <a:user>User4</a:user>
   <a:userid>9904</a:userid>
  </a:users> 
  <a:users>
   <a:user>User5</a:user>
   <a:userid>9905</a:userid>
  </a:users>   
</a:class>

Вот мой sites.xml: 

<?xml version="1.0"?>
<a:sites xmlns:a="a">
  <a:user>
   <a:hassite>true</a:hassite>
   <a:userid>9901</a:userid> 
  </a:user>
  <a:user>
   <a:hassite>false</a:hassite>
   <a:userid>9902</a:userid> 
  </a:user>
  <a:user>
   <a:hassite>true</a:hassite>
   <a:userid>9903</a:userid> 
  </a:user>
  <a:user>
   <a:hassite>false</a:hassite>
   <a:userid>9904</a:userid> 
  </a:user>
  <a:user>
   <a:hassite>false</a:hassite>
   <a:userid>9905</a:userid> 
  </a:user>  
</a:class>

Моя таблица стилей XSL: 

<?xml version="1.0"?>
<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:a="a">

    <xsl:template match="/a:class/a:users">

            <xsl:value-of select="document('sites.xml')/a:sites/a:user/a:userid"/> 

    </xsl:template>

</xsl:stylesheet>

Что я хочу сделать, так это отобразить имя пользователя и идентификатор пользователя из users.xml, затем прочитать sites.xml, и если идентификатор пользователя находится в xml, а значение <a:hassite> равно 'false', отобразить слово 'active '.

Может кто-нибудь дать мне несколько советов?

Ответы [ 2 ]

2 голосов
/ 26 марта 2011

Сравнение наборов узлов как раз для этого: 

<xsl:variable name="vSource2" select="document('sites.xml')">
<xsl:template match="/a:class/a:users">
    <xsl:if test="a:userid = $vSource2
                                /a:sites
                                   /a:user[a:hassite='true']
                                      /a:userid">
        <xsl:value-of select="a:userid"/>
    </xsl:if>
</xsl:template>

Таким образом, вы можете просто использовать шаблон 

<xsl:template match="/a:class/a:users[
                        a:userid = document('sites.xml')
                                      /a:sites
                                         /a:user[a:hassite='true']
                                            /a:userid
                     ]">
    <xsl:value-of select="a:userid"/>
</xsl:template>
1 голос
/ 26 марта 2011

Следующая таблица стилей: 

<xsl:stylesheet  version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:a="a">
    <xsl:output method="text"/>
    <xsl:variable name="sites" select="document('sites.xml')"/>
    <xsl:template match="a:users">
        (<xsl:value-of select="a:user"/> / <xsl:value-of select="a:userid"/>  
        <xsl:if 
            test="$sites/a:sites/a:user[a:userid=current()/a:userid]/a:hassite='false'"> / active</xsl:if>)
    </xsl:template>
</xsl:stylesheet>

Создает следующий вывод при применении к users.xml: 

(User1 / 9901) 
(User2 / 9902 / active) 
(User3 / 9903) 
(User4 / 9904 / active) 
(User5 / 9905 / active)

Настройка окончательного формата вывода по вкусу.

...